快捷开发 任性连接 :ESP32 Thing开发板评测

mkdir hardware

cd hardware

mkdir espressif

cd espressif

git clone https://github.com/espressif/arduino-esp32.git esp32

## Hint

Sometimes to program ESP32 via serial you must keep GPIO0 LOW during the programming process

int ledPin = 5;



void setup()

{

    pinMode(ledPin, OUTPUT);

    Serial.begin(115200);

}



void loop()

{

    Serial.println("Hello, My first ESP32 Thing program!");

    Serial.println(__DATE__" "__TIME__);    

    digitalWrite(ledPin, HIGH);

    delay(800);

    digitalWrite(ledPin, LOW);

    delay(800);

}

#include <WiFi.h>



// WiFi network name and password:

const char * networkName = "WIFI路由器SSID名称";

const char * networkPswd = "WIFI密码";



// Internet domain to request from:

const char * hostDomain = "www.21ic.com";

const int hostPort = 80;



const int BUTTON_PIN = 0;

const int LED_PIN = 5;



void setup()

{

  // Initilize hardware:

  Serial.begin(115200);

  pinMode(BUTTON_PIN, INPUT_PULLUP);

  pinMode(LED_PIN, OUTPUT);



  // Connect to the WiFi network (see function below loop)

  connectToWiFi(networkName, networkPswd);



  digitalWrite(LED_PIN, LOW); // LED off

  Serial.print("Press user button 0 to connect to ");

  Serial.println(hostDomain);

}



void loop()

{

  if (digitalRead(BUTTON_PIN) == LOW)

  { // Check if button has been pressed

    while (digitalRead(BUTTON_PIN) == LOW)

      ; // Wait for button to be released



    digitalWrite(LED_PIN, HIGH); // Turn on LED

    requestURL(hostDomain, hostPort); // Connect to server

    digitalWrite(LED_PIN, LOW); // Turn off LED

  }

}



void connectToWiFi(const char * ssid, const char * pwd)

{

  int ledState = 0;



  printLine();

  Serial.println("Connecting to WiFi network: " + String(ssid));



  WiFi.begin(ssid, pwd);



  while (WiFi.status() != WL_CONNECTED) 

  {

    // Blink LED while we're connecting:

    digitalWrite(LED_PIN, ledState);

    ledState = (ledState + 1) % 2; // Flip ledState

    delay(500);

    Serial.print(".");

  }



  Serial.println();

  Serial.println("WiFi connected!");

  Serial.print("IP address: ");

  Serial.println(WiFi.localIP());

}



void requestURL(const char * host, uint8_t port)

{

  printLine();

  Serial.println("Connecting to domain: " + String(host));



  // Use WiFiClient class to create TCP connections

  WiFiClient client;

  if (!client.connect(host, port))

  {

    Serial.println("connection failed");

    return;

  }

  Serial.println("Connected!");

  printLine();



  // This will send the request to the server

  client.print((String)"GET / HTTP/1.1\r\n" +

               "Host: " + String(host) + "\r\n" +

               "Connection: close\r\n\r\n");

  unsigned long timeout = millis();

  while (client.available() == 0) 

  {

    if (millis() - timeout > 5000) 

    {

      Serial.println(">>> Client Timeout !");

      client.stop();

      return;

    }

  }



  // Read all the lines of the reply from server and print them to Serial

  while (client.available()) 

  {

    String line = client.readStringUntil('\r');

    Serial.print(line);

  }



  Serial.println();

  Serial.println("closing connection");

  client.stop();

}



void printLine()

{

  Serial.println();

  for (int i=0; i<30; i++)

    Serial.print("-");

  Serial.println();

}

/*

 *  This sketch sends random data over UDP on a ESP32 device

 *

 */

#include <WiFi.h>

#include <WiFiUdp.h>



// WiFi network name and password:

const char * networkName = "WIFI路由器SSID名称";

const char * networkPswd = "WIFI密码";



//IP address to send UDP data to:

// either use the ip address of the server or 

// a network broadcast address

const char * udpAddress = "开网络助手的主机IP";

const int udpPort = 20000;



//Are we currently connected?

boolean connected = false;



//The udp library class

WiFiUDP udp;



void setup(){

  // Initilize hardware serial:

  Serial.begin(115200);

  

  //Connect to the WiFi network

  connectToWiFi(networkName, networkPswd);

}



void loop(){

  int tmpRand;

  //only send data when connected

  if(connected){

    //Send a packet

    udp.beginPacket(udpAddress,udpPort);

    tmpRand = rand();

    udp.printf("UDP Demo,It is a random number: %d\n", tmpRand);

    udp.endPacket();

    Serial.printf("Sending %d\n", tmpRand);

  }

  //Wait for 1 second

  delay(1000);

}



void connectToWiFi(const char * ssid, const char * pwd){

  Serial.println("Connecting to WiFi network: " + String(ssid));



  // delete old config

  WiFi.disconnect(true);

  //register event handler

  WiFi.onEvent(WiFiEvent);

  

  //Initiate connection

  WiFi.begin(ssid, pwd);



  Serial.println("Waiting for WIFI connection...");

}



//wifi event handler

void WiFiEvent(WiFiEvent_t event){

    switch(event) {

      case SYSTEM_EVENT_STA_GOT_IP:

          //When connected set 

          Serial.print("Connected! IP address: ");

          Serial.println(WiFi.localIP());  

          //initializes the UDP state

          //This initializes the transfer buffer

          udp.begin(WiFi.localIP(),udpPort);

          connected = true;

          break;

      case SYSTEM_EVENT_STA_DISCONNECTED:

          Serial.println("WiFi lost connection");

          connected = false;

          break;

    }

}

#include "SimpleBLE.h"

SimpleBLE ble;



void onButton(){

    String out = "BLE32 at: ";

    out += String(rand() % 100);

    Serial.println(out);

    ble.begin(out);

}



void setup() {

    Serial.begin(115200);

    Serial.setDebugOutput(true);

    ble.begin("ESP32 SimpleBLE");

    Serial.println("Press the user button to change the device name");

}



void loop() {

    static uint8_t lastPinState = 1;

    uint8_t pinState = digitalRead(0);

    if(!pinState && lastPinState){

        onButton();

    }

    lastPinState = pinState;

    while(Serial.available()) Serial.write(Serial.read());

}

void setup()

{

    //Setup DAC1

    pinMode(25, ANALOG);

    //Setup DAC2

    pinMode(26, ANALOG);     

}



void loop()

{

    uint8_t val1 = 0;

    uint8_t val2 = 0;

    static uint32_t x_idx = 0;



    //DAC1: Sine Wave

    val1 = INT8_MAX * (1 + sin(x_idx/(10*PI)));

    dacWrite(25, val1);



    //DAC2: Saw Wave

    val2 = (x_idx ++) % UINT8_MAX;

    dacWrite(26, val2);

}