发新帖我要提问
返回列表
打印

求救，汽車報警程序中遇到的問題

[复制链接]
2381|10
手机看帖
扫描二维码
随时随地手机跟帖
跳转到指定楼层
楼主
lpz110|  楼主 | 2010-9-11 10:34 | 只看该作者 |只看大图 回帖奖励 |倒序浏览 |阅读模式
摩托, 模拟, 电动, 电动车, 芯片
求救，汽車報警程序中遇到的問題，相信21icD的牛能幫我解決
我現在在做一個摩托车防盜項目，就是那報警聲不知道怎麼模擬啊，，沒有語音芯片，完全靠軟件模拟。（那种声音就是普通的摩托车。电动车的报警声音一样，）谁能教教我

使用特权

评论回复 赏

相关帖子
沙发
tyw| | 2010-9-11 11:36 | 只看该作者
GB 8108-1999 车用电子警报器.pdf (398.07 KB)



http://fuerhong.com/NewsShow_1271.aspx
http://hi.baidu.com/5281566/blog/item/9e3426d34fcc990c3bf3cf98.html

;ST套件产生报警音
;本实例的目的是让大家学会用单片机产生声音的方法，学会计算程序所用时间
;本实例的功能是能PIC16F84产生报警音，频率分两个0.1s第一个
;0.1S频率从1.8K-3.5K匀速增加第二个0.1S频率从3.5K-1.8K匀速减少,
;程序复位后,蜂鸣器开始报警
;PIC单片机学习网-----http://www.pic16.com
;烧写时应注意：配置位已经在程序中写明，加载HEX文件时会自动加载，烧写时不用再手动设置配置位。
;实验时请注意套件跳线选择；
;*****************************************************
  LIST P=16F84A,R=DEC         ;定义器件,默认为十进制
;-----------------------------------------------------
  __CONFIG B\\\'11111111110001\\\';_CP_OFF&_WDT_OFF&_PWRITE_ON&_XT_OSC
                                              ;没有代码保护
                                              ;看门狗关闭
                                              ;上电廷时器开启
                                              ;振荡器模式为XT
;-----------------------------------------------------
RTCC EQU 01H                ;定义各寄存器
PC EQU 02H
STATUS EQU 03H
C EQU 0
RP0 EQU 5
;----------------------
PORTA EQU 05H

TRISA EQU 05H
;-----------------------
SOUNDDELAY1 EQU 10H    ;声音频率变化计数器，从1.8~3.55KHZ
FRE_COUNT EQU 11H      ;同一频率的重复次数保存地址
FRE_REPEAT EQU 12H     
SOUND_TEMP EQU 13H
TEMP EQU 14H           ;暂存寄存器
S_LOOP EQU 46          ;93-47=46
S_MAX EQU 93           ;最低频率1.8K  93*3=280US*2
S_MIN EQU 47           ;最高频率3.55K  47*3=140*2
S_REPEAT EQU 4         ;同一频率重复次数
;--------------------
    ORG 0000H
MAIN
    CLRF PORTA         ;初始化IO口

    BSF STATUS,RP0     ;设置数据寄存器体1
    MOVLW 0000000B
    MOVWF TRISA        ;设置RA端口全部为输出
    BCF STATUS,RP0     ;恢复数据寄存器体0
LOOP
    CALL SOUND200MS    ;调用报警200MS子程序
    GOTO LOOP         ;反复循环报警
;-------------------------------
SOUND200MS
    MOVLW S_LOOP
    MOVWF FRE_COUNT     ;46=93-47 最低频率的计数减去最高频率的计数等于频率变化的次数
SOUND_LH_LP
    MOVLW S_REPEAT      ;同一频率重复次数送FRE_REPEAT
    MOVWF FRE_REPEAT
    MOVFW FRE_COUNT
    ADDLW S_MIN        ;计数值加最小值
    MOVWF TEMP
REPEAT0_LP
    MOVFW TEMP
    BSF PORTA,0      
    CALL SOUNDDELAY0   ;廷时W*3US
    BCF PORTA,0
    MOVFW TEMP
    CALL SOUNDDELAY0
    DECFSZ FRE_REPEAT,1 ;每四次减频率计数一次
    GOTO REPEAT0_LP
    DECFSZ FRE_COUNT,1
    GOTO SOUND_LH_LP
SOUND_HL
    MOVLW S_LOOP
    MOVWF FRE_COUNT   ;46=93-47
SOUND_HL_LP
    MOVLW S_REPEAT    ;同一频率重复次数送FRE_REPEAT
    MOVWF FRE_REPEAT
    MOVFW FRE_COUNT
    SUBLW S_MAX       ;最大值减计数值
    MOVWF TEMP
REPEAT1_LP
    MOVFW TEMP
    BSF PORTA,0
    CALL SOUNDDELAY0    ;廷时W*3US
    BCF PORTA,0
    MOVFW TEMP
    CALL SOUNDDELAY0
    DECFSZ FRE_REPEAT,1;四次减频率计数一次
    GOTO REPEAT1_LP
    DECFSZ FRE_COUNT,1
    GOTO SOUND_HL_LP
SOUND_END
    RETLW 0
;------------------------------
SOUNDDELAY0
    MOVWF SOUNDDELAY1     ;廷时W*3US+1US
SOUNDDELAYUS_1
    DECFSZ SOUNDDELAY1,1
    GOTO SOUNDDELAYUS_1
    RETLW 0
;------------------------
    END

--------------------------------------------------------------------------------

--  作者：陈学乾
--  发布时间：2004-8-26 12:33:25

--  

;ST套件产生450hz低音
;本实例的目的是让大家学会用单片机产生声音的方法，学会计算程序所用时间
;本实例的功能是能PIC16F84产生低音，
;450HZ,相当于450HZ的方波信号发生器。
;程序复位后,蜂鸣器开始发音
;PIC单片机学习网-----http://www.pic16.com
;烧写时应注意：配置位已经在程序中写明，加载HEX文件时会自动加载，烧写时不用再手动设置配置位。
;实验时请注意套件跳线选择；
;*****************************************************
  LIST P=16F84A,R=DEC         ;定义器件,默认为十进制
;-----------------------------------------------------
  __CONFIG B\\\'11111111110001\\\';_CP_OFF&_WDT_OFF&_PWRITE_ON&_XT_OSC
                                              ;没有代码保护
                                              ;看门狗关闭
                                              ;上电廷时器开启
                                              ;振荡器模式为XT
;-----------------------------------------------------
RTCC EQU 01H                ;定义各寄存器
PC EQU 02H
STATUS EQU 03H
C EQU 0
RP0 EQU 5
;----------------------
PORTA EQU 05H

TRISA EQU 05H
;-----------------------
SOUNDDELAY1 EQU 10H    ;声音频率变化计数器，从1.1K~0.5KHZ
;--------------------
    ORG 0000H
MAIN
    CLRF PORTA         ;初始化IO口

    BSF STATUS,RP0     ;设置数据寄存器体1
    MOVLW 0000000B
    MOVWF TRISA        ;设置RA端口全部为输出
    BCF STATUS,RP0     ;恢复数据寄存器体0
SOUND
    MOVLW 222           ;450HZ反复循环
    BSF PORTA,0
    CALL SOUNDDELAY0    ;廷时W*5US
    BCF PORTA,0
    MOVLW 222
    CALL SOUNDDELAY0
    GOTO SOUND
;------------------------------
SOUNDDELAY0
    MOVWF SOUNDDELAY1     ;廷时W*5US+1US
SOUNDDELAYUS_1
    NOP
    NOP
    DECFSZ SOUNDDELAY1,1
    GOTO SOUNDDELAYUS_1
    RETLW 0
;------------------------
    END

--------------------------------------------------------------------------------

--  作者：陈学乾
--  发布时间：2004-8-26 12:33:56

--  

;ST套件产生救护音
;本实例的目的是让大家学会用单片机产生声音的方法，学会计算程序所用时间
;本实例的功能是能PIC16F84产生救护音，频率分两个1S第一个
;1S频率是440HZ,第二个1S频率是180HZ,反复循环
;程序复位后,蜂鸣器开始报警
;PIC单片机学习网-----http://www.pic16.com
;烧写时应注意：配置位已经在程序中写明，加载HEX文件时会自动加载，烧写时不用再手动设置配置位。
;实验时请注意套件跳线选择；
;*****************************************************
  LIST P=16F84A,R=DEC         ;定义器件,默认为十进制
;-----------------------------------------------------
  __CONFIG B\\\'11111111110001\\\';_CP_OFF&_WDT_OFF&_PWRITE_ON&_XT_OSC
                                              ;没有代码保护
                                              ;看门狗关闭
                                              ;上电廷时器开启
                                              ;振荡器模式为XT
;-----------------------------------------------------
RTCC EQU 01H                ;定义各寄存器
PC EQU 02H
STATUS EQU 03H
C EQU 0
RP0 EQU 5
;----------------------
PORTA EQU 05H
TRISA EQU 05H
;-----------------------
SOUNDDELAY1 EQU 10H      ;声音频率高低电平廷时计数器
FRE_REPEATH EQU 11H      ;同一频率的重复次数外部循环
FRE_REPEATL EQU 12H      ;同一频率的重复次数内部循环
TEMP EQU 14H           ;暂存寄存器
;--------------------
    ORG 0000H
MAIN
    CLRF PORTA         ;初始化IO口

    BSF STATUS,RP0     ;设置数据寄存器体1
    MOVLW 0000000B
    MOVWF TRISA        ;设置RA端口全部为输出
    BCF STATUS,RP0     ;恢复数据寄存器体0
LOOP
    CALL SOUND2S       ;调用报警200MS子程序
    GOTO LOOP          ;反复循环报警
;-------------------------------
SOUND2S                          ;先440HZ 1S
    MOVLW 189
    MOVWF TEMP         ;440HZ频率高低电平廷时值送TEMP 1S/[(189*6)US*2]=440HZ
    MOVLW 2             ;同一频率重复次数外部循环送初值
    MOVWF FRE_REPEATH
SOUND2S_1
    MOVLW 220
    MOVFW FRE_REPEATL     ;同一频率重复次数内部循环送初值220*2=440次,440HZ频率重复440次即1S
REPEAT0_LP
    MOVFW TEMP
    BSF PORTA,0      
    CALL SOUNDDELAY0   ;廷时W*6US 440hz正半周
    BCF PORTA,0
    MOVFW TEMP
    CALL SOUNDDELAY0    ;廷时W*6US 440hz负半周
    DECFSZ FRE_REPEATL,1
    GOTO REPEAT0_LP
    DECFSZ FRE_REPEATH,1    ;同一频率持续1S
    GOTO SOUND2S_1
SOUND2S_B                  ;再180HZ  1S
    MOVLW 231
    MOVWF TEMP         ;180HZ频率高低电平廷时值送TEMP 1S/[(231*2*6)US*2]=180HZ
    MOVLW 180
    MOVFW FRE_REPEATL     ;同一频率重复次数送初值180HZ频率重复180次即1S
REPEAT0_LP_B
    MOVFW TEMP
    BSF PORTA,0      
    CALL SOUNDDELAY0   ;廷时W*6US*2  180HZ正半周
    MOVFW TEMP
    CALL SOUNDDELAY0
    BCF PORTA,0
    MOVFW TEMP
    CALL SOUNDDELAY0   ;廷时W*6US*2  180HZ负半周
    MOVFW TEMP
    CALL SOUNDDELAY0
    DECFSZ FRE_REPEATL,1  ;同一频率持续1S
    GOTO REPEAT0_LP_B
SOUND_END
    RETLW 0
;------------------------------
SOUNDDELAY0
    MOVWF SOUNDDELAY1     ;廷时W*6US+1US
SOUNDDELAYUS_1
    nop
    nop
    nop
    DECFSZ SOUNDDELAY1,1
    GOTO SOUNDDELAYUS_1
    RETLW 0
;------------------------
    END

--------------------------------------------------------------------------------

--  作者：陈学乾
--  发布时间：2004-8-26 12:34:23

--  

;ST套件产生开道音
;本实例的目的是让大家学会用单片机产生声音的方法，学会计算程序所用时间
;本实例的功能是能PIC16F84产生开道音，每一个3S内频率
;从1.1K-0.5K匀速减少,反复循环。
;程序复位后,蜂鸣器开始报警
;PIC单片机学习网-----http://www.pic16.com
;烧写时应注意：配置位已经在程序中写明，加载HEX文件时会自动加载，烧写时不用再手动设置配置位。
;实验时请注意套件跳线选择；
;*****************************************************
  LIST P=16F84A,R=DEC         ;定义器件,默认为十进制
;-----------------------------------------------------
  __CONFIG B\\\'11111111110001\\\';_CP_OFF&_WDT_OFF&_PWRITE_ON&_XT_OSC
                                              ;没有代码保护
                                              ;看门狗关闭
                                              ;上电廷时器开启
                                              ;振荡器模式为XT
;-----------------------------------------------------
RTCC EQU 01H                ;定义各寄存器
PC EQU 02H
STATUS EQU 03H
C EQU 0
RP0 EQU 5
;----------------------
PORTA EQU 05H

TRISA EQU 05H
;-----------------------
SOUNDDELAY1 EQU 10H    ;声音频率变化计数器，从1.1K~0.5KHZ
FRE_COUNT EQU 11H      ;同一频率的重复次数保存地址
FRE_REPEAT EQU 12H     
SOUND_TEMP EQU 13H
TEMP EQU 14H           ;暂存寄存器
S_LOOP EQU 136         ;250-114=136
S_MAX EQU 250           ;最低频率0.5K  250*4=1000 *2
S_MIN EQU 114           ;最高频率1.1K  114*4=456 *2
S_REPEAT EQU 17         ;同一频率重复次数
;--------------------
    ORG 0000H
MAIN
    CLRF PORTA         ;初始化IO口

    BSF STATUS,RP0     ;设置数据寄存器体1
    MOVLW 0000000B
    MOVWF TRISA        ;设置RA端口全部为输出
    BCF STATUS,RP0     ;恢复数据寄存器体0
LOOP
    CALL SOUND3S    ;调用报警3S子程序
    GOTO LOOP         ;反复循环报警
;-------------------------------
SOUND3S
    MOVLW S_LOOP
    MOVWF FRE_COUNT   ;136=250-114
SOUND_HL_LP
    MOVLW S_REPEAT    ;同一频率重复次数送FRE_REPEAT
    MOVWF FRE_REPEAT
    MOVFW FRE_COUNT
    SUBLW S_MAX       ;最大值减计数值
    MOVWF TEMP
REPEAT1_LP
    MOVFW TEMP
    BSF PORTA,0
    CALL SOUNDDELAY0    ;廷时W*4US
    BCF PORTA,0
    MOVFW TEMP
    CALL SOUNDDELAY0
    DECFSZ FRE_REPEAT,1;17次减频率计数一次
    GOTO REPEAT1_LP
    DECFSZ FRE_COUNT,1
    GOTO SOUND_HL_LP
SOUND_END
    RETLW 0
;------------------------------
SOUNDDELAY0
    MOVWF SOUNDDELAY1     ;廷时W*4US+1US
SOUNDDELAYUS_1
    NOP
    DECFSZ SOUNDDELAY1,1
    GOTO SOUNDDELAYUS_1
    RETLW 0
;------------------------
    END

--------------------------------------------------------------------------------

--  作者：陈学乾
--  发布时间：2004-8-26 12:34:47

--  

;ST套件产生汽笛音800HZ
;本实例的目的是让大家学会用单片机产生声音的方法，学会计算程序所用时间
;本实例的功能是能PIC16F84产生汽笛音800HZ
;相当于800HZ的方波信号发生器。
;程序复位后,蜂鸣器开始发音
;PIC单片机学习网-----http://www.pic16.com
;烧写时应注意：配置位已经在程序中写明，加载HEX文件时会自动加载，烧写时不用再手动设置配置位。
;实验时请注意套件跳线选择；
;*****************************************************
  LIST P=16F84A,R=DEC         ;定义器件,默认为十进制
;-----------------------------------------------------
  __CONFIG B\\\'11111111110001\\\';_CP_OFF&_WDT_OFF&_PWRITE_ON&_XT_OSC
                                              ;没有代码保护
                                              ;看门狗关闭
                                              ;上电廷时器开启
                                              ;振荡器模式为XT
;-----------------------------------------------------
RTCC EQU 01H                ;定义各寄存器
PC EQU 02H
STATUS EQU 03H
C EQU 0
RP0 EQU 5
;----------------------
PORTA EQU 05H

TRISA EQU 05H
;-----------------------
SOUNDDELAY1 EQU 10H    ;声音频率变化计数器，从1.1K~0.5KHZ
;--------------------
    ORG 0000H
MAIN
    CLRF PORTA         ;初始化IO口

    BSF STATUS,RP0     ;设置数据寄存器体1
    MOVLW 0000000B
    MOVWF TRISA        ;设置RA端口全部为输出
    BCF STATUS,RP0     ;恢复数据寄存器体0
SOUND
    MOVLW 125           ;800HZ反复循环
    BSF PORTA,0
    CALL SOUNDDELAY0    ;廷时W*5US
    BCF PORTA,0
    MOVLW 125
    CALL SOUNDDELAY0
    GOTO SOUND
;------------------------------
SOUNDDELAY0
    MOVWF SOUNDDELAY1     ;廷时W*5US+1US
SOUNDDELAYUS_1
    NOP
    NOP
    DECFSZ SOUNDDELAY1,1
    GOTO SOUNDDELAYUS_1
    RETLW 0
;------------------------
    END

--------------------------------------------------------------------------------

--  作者：陈学乾
--  发布时间：2004-8-26 12:35:14

--  

;ST套件产生治安音
;本实例的目的是让大家学会用单片机产生声音的方法，学会计算程序所用时间
;本实例的功能是能PIC16F84产生治安音，频率分两个0.4s第一个
;0.4S频率从1.8K-2.2K匀速增加第二个0.4S频率从2.2K-1.8K匀速减少,
;程序复位后,蜂鸣器开始报警
;PIC单片机学习网-----http://www.pic16.com
;烧写时应注意：配置位已经在程序中写明，加载HEX文件时会自动加载，烧写时不用再手动设置配置位。
;实验时请注意套件跳线选择；
;*****************************************************
  LIST P=16F84A,R=DEC         ;定义器件,默认为十进制
;-----------------------------------------------------
  __CONFIG B\\\'11111111110001\\\';_CP_OFF&_WDT_OFF&_PWRITE_ON&_XT_OSC
                                              ;没有代码保护
                                              ;看门狗关闭
                                              ;上电廷时器开启
                                              ;振荡器模式为XT
;-----------------------------------------------------
RTCC EQU 01H                ;定义各寄存器
PC EQU 02H
STATUS EQU 03H
C EQU 0
RP0 EQU 5
;----------------------
PORTA EQU 05H

TRISA EQU 05H
;-----------------------
SOUNDDELAY1 EQU 10H    ;声音频率变化计数器，从0.8~2.2KHZ
FRE_COUNT EQU 11H      ;同一频率的重复次数保存地址
FRE_REPEAT EQU 12H     
SOUND_TEMP EQU 13H
TEMP EQU 14H           ;暂存寄存器
S_LOOP EQU 132          ;208-76=132
S_MAX EQU 208           ;最低频率0.8K  208*3=624US *2
S_MIN EQU 76           ;最高频率2.2K  76*3=228 *2
S_REPEAT EQU 5         ;同一频率重复次数   5*132个变化点*(1S/1.5KHZ)=0.4S
;--------------------
    ORG 0000H
MAIN
    CLRF PORTA         ;初始化IO口

    BSF STATUS,RP0     ;设置数据寄存器体1
    MOVLW 0000000B
    MOVWF TRISA        ;设置RA端口全部为输出
    BCF STATUS,RP0     ;恢复数据寄存器体0
LOOP
    CALL SOUND800MS    ;调用报警800MS子程序
    GOTO LOOP          ;反复循环报警
;-------------------------------
SOUND800MS
    MOVLW S_LOOP
    MOVWF FRE_COUNT     ;132=208-76 最低频率的计数减去最高频率的计数等于频率变化的次数
SOUND_LH_LP
    MOVLW S_REPEAT      ;同一频率重复次数送FRE_REPEAT
    MOVWF FRE_REPEAT
    MOVFW FRE_COUNT
    ADDLW S_MIN        ;计数值加最小值
    MOVWF TEMP
REPEAT0_LP
    MOVFW TEMP
    BSF PORTA,0      
    CALL SOUNDDELAY0   ;廷时W*3US
    BCF PORTA,0
    MOVFW TEMP
    CALL SOUNDDELAY0
    DECFSZ FRE_REPEAT,1 ;每五次减频率计数一次
    GOTO REPEAT0_LP
    DECFSZ FRE_COUNT,1
    GOTO SOUND_LH_LP
SOUND_HL
    MOVLW S_LOOP
    MOVWF FRE_COUNT   ;132=208-76
SOUND_HL_LP
    MOVLW S_REPEAT    ;同一频率重复次数送FRE_REPEAT
    MOVWF FRE_REPEAT
    MOVFW FRE_COUNT
    SUBLW S_MAX       ;最大值减计数值
    MOVWF TEMP
REPEAT1_LP
    MOVFW TEMP
    BSF PORTA,0
    CALL SOUNDDELAY0    ;廷时W*3US
    BCF PORTA,0
    MOVFW TEMP
    CALL SOUNDDELAY0
    DECFSZ FRE_REPEAT,1;五次减频率计数一次
    GOTO REPEAT1_LP
    DECFSZ FRE_COUNT,1
    GOTO SOUND_HL_LP
SOUND_END
    RETLW 0
;------------------------------
SOUNDDELAY0
    MOVWF SOUNDDELAY1     ;廷时W*3US+1US
SOUNDDELAYUS_1
    DECFSZ SOUNDDELAY1,1
    GOTO SOUNDDELAYUS_1
    RETLW 0
;------------------------
    END

使用特权

评论回复 赏
板凳
chunyang| | 2010-9-11 17:27 | 只看该作者
最好用一片语音芯片或数字录音芯片来实现，音质会好很多，软件也会大幅简化，从可靠性设计和实用化的角度讲，应该采用专门音源。

使用特权

评论回复 赏
地板
zhlok520| | 2010-9-11 17:45 | 只看该作者
哪里有报警 哪里就有chunyang大叔的解说，还有tyw的资料:victory:

使用特权

评论回复 赏
5楼
yanwen217| | 2010-9-11 21:53 | 只看该作者
呵呵，chunyang大叔说的很对，我们当初在做这个时也想着节省成本采用软件实现，调试出来的音质效果不好，没有达到客户的要求，最后还是加上了一颗flash 存储音频数据和音频功放。
楼主如果用到音频功放，考虑到音质，最好选用AB类的，比如SGM4890、SGM4971、HT82V739等等

使用特权

评论回复 赏
6楼
chunyang| | 2010-9-11 23:16 | 只看该作者
用Flash存储数字音频数据并用MCU还原的成本高于使用音乐片或数字录音机，连你的MCU都因此需要更多的资源和更强的处理能力，钱没花在刀刃上反而浪费在无关紧要的地方，还为可靠性带来了不小隐患，还是应回到性价比最高的方案上来，做产品要考虑长期量产。
音频功放的选择很简单，如果供电电压准许，可以选择的太多，根据需要的输出功率选择就是，音质根本不是该考虑的，音源不是高保真的，任何音频功放都可满足，无所谓什么AB类，方向整个歪了，这样做出来的产品谈不上什么性价比。

使用特权

评论回复 赏
7楼
jzfbbs| | 2010-9-12 12:17 | 只看该作者
T叔真是厉害，什么玩意都有。这种报警音程序；完全可以由软件来实现。用这么多硬件来做，产品没有竞争力。

使用特权

评论回复 赏
8楼
chunyang| | 2010-9-12 13:21 | 只看该作者
用硬件做没有竞争力么？

一片音乐片几毛钱，MCU可用比纯软件实现所需的档次更低，成本单凭此就已经找回，大批量时MCU的差价更大，用音乐片才是成本最低的，音质则远比软件模拟强，哪个更有竞争力？

使用特权

评论回复 赏
9楼
xwj| | 2010-9-12 13:23 | 只看该作者
呵呵，LS正解

使用特权

评论回复 赏
10楼
yanwen217| | 2010-9-12 21:21 | 只看该作者
呵呵，以前公司的做法，方案定型是老大说了算，做小弟的只能照着实现，至于综合成本上，对公司而言也不见得高，因为有一堆的库存要清，方案本来就没有最佳的，只有更佳的。

使用特权

评论回复 赏
11楼
chunyang| | 2010-9-12 23:14 | 只看该作者
特殊情况不代表具有普适性。

使用特权

评论回复 赏
返回列表
发新帖 我要提问
高级模式
B Color Image Link Quote Code 收费 Smilies
您需要登录后才可以回帖 登录 | 注册

本版积分规则

lpz110

0

主题

28

帖子

1

粉丝