请教STC89C52的T2中断问题

只看该作者 · 2008-12-8 07:53

做一个程序用到STC89C52的T2(T0,T1用了),不知怎么进不了中断，急！请各位大侠指教，程序如下：
SPK       EQU    P0.0        ;=0,ring
RCAP2L      EQU   0CAH
RCAP2H      EQU   0CBH
TL2         EQU   0CCH
TH2         EQU   0CDH
T2CON       EQU   0C8H
T2MOD       EQU   0C9H
TR2         EQU   T2CON.2
;===============================
ORG 0000H
Q0000: LJMP MAIN
;================================
;定时器T2
;===============================
ORG 002BH
CPL SPK
RETI
;===============================
ORG 0100H
MAIN:   CLR A
        MOV TL2,A
        MOV TH2,A
        MOV RCAP2L,A
        MOV RCAP2H,A
        MOV T2MOD,#00H ;
        MOV T2CON,#00H ;自动装载，停止
        SETB EA
        CLR  T2CON.4  ;EXEN2
        SETB IE.6  ;ET2
        SETB TR2
WAIT:   NOP
        NOP
        JMP WAIT
  END

只看该作者 · 2008-12-8 09:22

CLR  T2CON.4  ;EXEN2
SETB IE.6  ;ET2
应为
CLR  T2CON.3  ;EXEN2
SETB IE.5  ;ET2

只看该作者 · 2008-12-8 10:52

我改过来了，可是蜂鸣器还是不响啊（线路没问题，单独送指令，蜂鸣器会响）

只看该作者 · 2008-12-8 11:52

SPK        EQU    P0.0        ;=0,ring
RCAP2L      EQU   0CAH
RCAP2H      EQU   0CBH
TL2         EQU   0CCH
TH2         EQU   0CDH
T2CON       EQU   0C8H
T2MOD       EQU   0C9H
TR2         EQU   T2CON.2
TF2         EQU   T2CON.7
EXF2        EQU   T2CON.6
;===============================
ORG 0000H
Q0000: LJMP MAIN
;================================
;定时器T2
;===============================
ORG 002BH
CLR TF2    ;这两条很重要，否则不能自动装载
CLR EXF2   ;
CPL SPK
RETI
;===============================
ORG 0100H
MAIN:   CLR A
        MOV TL2,A
        MOV TH2,A
        MOV RCAP2L,A
      MOV RCAP2H,#0EEH
      MOV T2MOD,#00H ;T2OE不为1即可
      MOV T2CON,#00H ;自动装载，停止
      SETB EA
      SETB IE.5  ;ET2
      SETB TR2
WAIT:   NOP
        NOP
      JMP WAIT
      END