4位BCD码转二进制的问题

只看该作者 · 2009-5-18 14:09

大家好，我是一名单片机初学者，请多指教
关于4位BCD码转二进制的问题，我的编程思路如下，大家帮忙看看这样对吗？谢谢

4位BCD码A B C D
转二进制存入R0 R1

C X 10 + D -> R1
A X 10 + B -> R3
R3 X 100
低字节 + R1 -> R1
高字节 + 进位 -> R0

以上是我的思路，我在网上找了个程序如下，有个地方看不懂，下面箭头的位置，为什么是乘以250，而不是乘以10呢
; INPUT:  R3:R2 -- BCD
   ; OUTPUT: R5:R4 -- BIN
   ; USE: A, B, PWS
   MOV A, R2
   CALL BCD_BYTE2BIN
   MOV R4, A
   MOV A, R3
   CALL BCD_BYTE2BIN
   MOV B, #100
   MUL AB
   ADD A, R4
   MOV R4, A
   CLR A
   ADDC A, B
   MOV R5, A
   RET

BCD_BYTE2BIN:
   ; 10*Y + X = (16*Y + X)-6*Y = 250 * Y + (16*Y + X) - 256 * Y
   MOV R5, A
   ANL A, #0F0H
   SWAP A
   MOV B, #250  ; <-  <-  <-
   MUL AB
   ADD A, R5
   RET

只看该作者 · 2009-5-18 15:41

程序已经给你注释过了
; 10*Y + X = (16*Y + X)-6*Y = 250 * Y + (16*Y + X) - 256 * Y

1万 · 2009-5-18 16:58

BCD_BYTE2BIN:
   ; 10*Y + X = (16*Y + X)-6*Y = 250 * Y + (16*Y + X) - 256 * Y
   MOV R5, A
   ANL A, #0F0H
   SWAP A
   MOV B, #250  ; <-  <-  <-
   MUL AB
   ADD A, R5
   RET

常规计算方法:
    MOV R5, A
    ANL A, #0FH
    XCH A, R5
    XRL A, R5
    SWAP A
    MOV B, #10
    MUL AB
    ADD A, R5
    RET

只看该作者 · 2009-5-19 09:38

只看该作者 · 2009-5-19 10:58

= (4y + y) *2 + x = (((y<<2) + y) << 1) + x

这种做法，全部是移位和加法，效率更高。

1万 · 2009-5-19 18:32

;你的计算方法在51要11周期, 我的只要10周期, 你的13字节, 我的9字节
      MOV R5, A
      ANL A, #0F0H
      SWAP A
      MOV R4, A
      RL A
      RL A
      ADD A, R4
      RL A

      XCH A, R5
      ANL A, #0FH
      ADD A, R5

只看该作者 · 2009-5-19 20:35

我给出的是一种通用算法，的确没有考虑cpu的特殊性。

只看该作者 · 2009-5-21 11:09

4位BCD码，由高到低分别存在D24 D23 D22 D21四个单元

BCD_BIN:  MOV A,D22             ;4位BCD码转二进制数,低位存在D2L单元,高位存在D2H单元
          MOV B,#0AH
          MUL AB
          ADD A,D21
          MOV D2L,A
          MOV A,D24
          MOV B,#0AH
          MUL AB
          ADD A,D23
          MOV B,#100
          MUL AB
          MOV D2H,B
          ADD A,D2L
          JNC OVER2
          INC D2H
OVER2:    MOV D2L,A
          RET