动态扫描显示接口电路及程序

只看该作者 · 2015-11-18 20:37

在单片机系统中动态扫描显示接口是单片机中应用最为广泛的一种显示方式之一。其接口电路是把所有显示器的8个笔划段a-h同名端连在一起，而每一个显示器的公共极COM是各自独立地受I/O线控制。CPU向字段输出口送出字形码时，所有显示器接收到相同的字形码，但究竟是那个显示器亮，则取决于COM端，而这一端是由I/O控制的，所以我们就能自行决定何时显示哪一位了。而所谓动态扫描就是指我们采用分时的办法，轮流控制各个显示器的COM端，使各个显示器轮流点亮。在http://www.51hei.com还有很多关于单片机显示接口的**，大家可以参考一下在轮流点亮扫描过程中，每位显示器的点亮时间是极为短暂的（约1ms），但由于人的视觉暂留现象及发光二极管的余辉效应，尽管实际上各位显示器并非同时点亮，但只要扫描的速度足够快，给人的印象就是一组稳定的显示数据，不会有闪烁感。
下图所示就是我们的单片机实验板上的动态扫描接口。由89c51的P0口能灌入较大的电流，所以我们采用共阳的数码管，并且不用限流电阻，而只是用两只1N4004进行降压后给数码管供电，这里仅用了两只，实际上还能扩充。它们的公共端则由PNP型三极管8550控制，显然，如果8550导通，则对应的数码管就能亮，而如果8550截止，则对应的数码管就不可能亮，8550是由P2.7，P2.6控制的。这样我们就能通过控制P27、P26达到控制某个数码管亮或灭的目的。
下面的这个单片机程序，就是用实验板上的数码管显示0和1。
FIRST EQU P2.7 ;第一位数码管的位控制
SECOND EQU P2.6 ;第二位数码管的位控制
DISPBUFF EQU 5AH ;显示缓冲区为5AH和5BH
ORG 0000H
AJMP START
ORG 30H
START:
MOV SP,#5FH ;设置堆栈
MOV P1,#0FFH
MOV P0,#0FFH
MOV P2,#0FFH ;初始化，所显示器，LED灭
MOV DISPBUFF,#0 ;第一位显示0
MOV DISPBUFF+1,#1 ;第二握显示1
LOOP:
LCALL DISP ;调用显示程序
AJMP LOOP
;主程序到此结束
DISP:
PUSH ACC ;ACC入栈
PUSH PSW ;PSW入栈
MOV A,DISPBUFF ;取第一个待显示数
MOV DPTR,#DISPTAB ;字形表首地址
MOVC A,@A+DPTR ;取字形码
MOV P0,A ;将字形码送P0位（段口）
CLR FIRST ;开第一位显示器位口
LCALL DELAY ;延时1毫秒
SETB FIRST ;关闭第一位显示器（开始准备第二位的数据）
MOV A,DISPBUFF+1 ;取显示缓冲区的第二位
MOV DPTR,#DISPTAB
MOVC A,@A+DPTR
MOV P0,A ;将第二个字形码送P0口
CLR SECOND ;开第二位显示器
LCALL DELAY ;延时
SETB SECOND ;关第二位显示
POP PSW
POP ACC
RET
DELAY: ;延时1毫秒
PUSH PSW
SETB RS0
MOV R7,#50
D1: MOV R6,#10
D2: DJNZ R6,$
DJNZ R7,D1
POP PSW
RET
DISPTAB:DB 28H,7EH,0a4H,64H,72H,61H,21H,7CH,20H,60H
END

只看该作者 · 2015-11-18 20:37

从上面的单片机例程中能看出，动态扫描显示必须由CPU持续地调用显示程序，才能保证持续持续的显示。
上面的这个程序能实现数字的显示，但不太实用，为什么呢？这里仅是显示两个数字，并没有做其他的工作，因此，两个数码管轮流显示1毫秒，没有问题，实际的工作中，当然不可能只显示两个数字，还是要做其他的事情的，这样在二次调用显示程序之间的时间间隔就不一不定了，如果时间间隔比较长，就会使显示不连续。而实际工作中是很难保证所有工作都能在很短时间内完成的。况且这个显示程序也有点“浪费”，每个数码管显示都要占用1个毫秒的时间，这在很多合是不允许的，怎么办呢？我们能借助于定时器，定时时间一到，产生中断，点亮一个数码管，然后马上返回，这个数码管就会一直亮到下一次定时时间到，而不用调用延时程序了，这段时间能留给主程序干其他的事。到下一次定时时间到则显示下一个数码管，这样就很少浪费了。
Counter EQU 59H ;计数器，显示程序通过它得知现正显示哪个数码管
FIRST EQU P2.7 ;第一位数码管的位控制
SECOND EQU P2.6 ;第二位数码管的位控制
DISPBUFF EQU 5AH ;显示缓冲区为5AH和5BH
ORG 0000H
AJMP START
ORG 000BH ;定时器T0的入口
AJMP DISP ;显示程序
ORG 30H
START:
MOV SP,#5FH ;设置堆栈
MOV P1,#0FFH
MOV P0,#0FFH
MOV P2,#0FFH ;初始化，所显示器，LED灭
MOV TMOD,#00000001B ;定时器T0工作于模式1（16位定时/计数模式）
MOV TH0,#HIGH(65536-2000)
MOV TL0,#LOW(65536-2000)
SETB TR0
SETB EA
SETB ET0
MOV Counter,#0 ;计数器初始化
MOV DISPBUFF,#0 ;第一位始终显示0
MOV A,#0
LOOP:
MOV DISPBUFF+1,A ;第二位轮流显示0-9
INC A
LCALL DELAY
CJNE A,#10,LOOP
MOV A,#0
AJMP LOOP ;在此中间能按排任意程序，这里仅作示范。
;主程序到此结束
DISP: ;定时器T0的中断响应程序
PUSH ACC ;ACC入栈
PUSH PSW ;PSW入栈
MOV TH0,#HIGH(65536-2000) ;定时时间为2000个周期，约2170微秒（11.0592M）
MOV TL0,#LOW(65536-2000)
SETB FIRST
SETB SECOND ;关显示
MOV A,#DISPBUFF ;显示缓冲区首地址
ADD A,Counter
MOV R0,A
MOV A,@R0 ;根据计数器的值取对应的显示缓冲区的值
MOV DPTR,#DISPTAB ;字形表首地址
MOVC A,@A+DPTR ;取字形码
MOV P0,A ;将字形码送P0位（段口）
MOV A,Counter ;取计数器的值
JZ DISPFIRST ;如果是0则显示第一位
CLR SECOND ;不然显示第二位
AJMP DISPNEXT
DISPFIRST:
CLR FIRST ;显示第一位
DISPNEXT:
INC Counter ;计数器加1
MOV A,Counter
DEC A ;如果计数器计到2，则让它回0
DEC A
JZ RSTCOUNT
AJMP DISPEXIT
RSTCOUNT:
MOV Counter,#0 ;计数器的值只能是0或1
DISPEXIT:
POP PSW
POP ACC
RETI
DELAY: ;延时130毫秒
PUSH PSW
SETB RS0
MOV R7,#255
D1: MOV R6,#255
D2: NOP
NOP
NOP
NOP
DJNZ R6,D2
DJNZ R7,D1
POP PSW
RET
DISPTAB:DB 28H,7EH,0a4H,64H,72H,61H,21H,7CH,20H,60H
END

只看该作者 · 2015-11-18 20:39

从上面的单片机程序能看出，动态显示和静态显示相比，程序稍有点复杂，不过，这是值得的。这个程序有一定的通用性，只要改变端口的值及计数器的值就能显示更多位数了。下面给出显示程序的流程图。<动态扫描程序框图>

只看该作者 · 2015-11-19 21:37

单片机系统中动态扫描显示接口是单片机中应用最为广泛的一种显示方式之一

只看该作者 · 2015-11-19 23:05

由89c51的P0口能灌入较大的电流，所以我们采用共阳的数码管，并且不用限流电阻，而只是用两只1N4004进行降压后给数码管供电，这里仅用了两只，实际上还能扩充

1万 · 2015-11-19 23:11

借助于定时器，定时时间一到，产生中断，点亮一个数码管，然后马上返回，这个数码管就会一直亮到下一次定时时间到，而不用调用延时程序了，这段时间能留给主程序干其他的事。到下一次定时时间到则显示下一个数码管，这样就很少浪费了。

只看该作者 · 2015-11-20 16:04

接口电路是把所有显示器的8个笔划段a-h同名端连在一起，而每一个显示器的公共极COM是各自独立地受I/O线控制

只看该作者 · 2015-11-20 16:32

动态扫描显示必须由CPU持续地调用显示程序，才能保证持续持续的显示。因此动态扫描实际上是不可取的，建议采用静态显示的方式，比如采用驱动器，MAX7219就是个很不错的选择。

只看该作者 · 2015-11-20 16:33

AX7219/MAX7221是一种集成化的串行输入/输出共阴极显示驱动器,它连接微处理器与8位数字的7段数字LED显示，也可以连接条线图显示器或者64个独立的LED。其上包括一个片上的B型BCD编码器、多路扫描回路，段字驱动器，而且还有一个8*8的静态RAM用来存储每一个数据。

1万 · 2015-11-21 10:58

由89c51的P0口能灌入较大的电流，所以我们采用共阳的数码管，并且不用限流电阻，而只是用两只1N4004进行降压后给数码管供电，这里仅用了两只，实际上还能扩充

1万 · 2015-11-21 21:26

在轮流点亮扫描过程中，每位显示器的点亮时间是极为短暂的（约1ms），但由于人的视觉暂留现象及发光二极管的余辉效应，尽管实际上各位显示器并非同时点亮，但只要扫描的速度足够快，给人的印象就是一组稳定的显示数据，不会有闪烁感。

只看该作者 · 2015-11-23 21:05

Counter EQU 59H ;计数器，显示程序通过它得知现正显示哪个数码管
FIRST EQU P2.7 ;第一位数码管的位控制
SECOND EQU P2.6 ;第二位数码管的位控制
DISPBUFF EQU 5AH ;显示缓冲区为5AH和5BH
ORG 0000H
这里ORG是什么意思？不懂这个，

只看该作者 · 2015-11-24 13:06

【12345678】

#include<reg52.h>

#define uintunsigned int

#define ucharunsigned char

uchar codeDisplsy[]={0xc0,0xf9,0xa4,0xb0,0x99,0x92,0x82,0xf8,0x80};

uchar codeTemble[]={0,1,2,3,4,5,6,7};

void delay(uint z)

{

uchar t;

while(z--) for(t=120;t>0;t--);

}

void main()

{

uchar i;

P0=0xff;

P1=0;

while(1)

{

if(i==8)

i=0;

P1=Temble;

P0=~Displsy[i+1];

i++;

delay(2);

}

【脉冲计时】

#include<reg52.h>

#define uintunsigned int

#define ucharunsigned char

uchar codeDisplay[]={0xc0,0xf9,0xa4,0xb0,0x99,0x92,0x82,0xf8,0x80,0x90};

uchar codeTemble[]={0,1,2,3,4,5,6,7};

uchar Flag;

uint Num;

void delay(uint z)

{

uchar t;

while(z--) for(t=120;t>0;t--);

}

voidTest2(void)

{

TR1 = 1;

while(1)

{

      Num = TH1;
      Num = Num << 8;
      Num |= TL1;
      P1 = 7;
      P0 = ~Display[Num%10];
      delay(3);
      P1 = 6;
      P0 = ~Display[Num%100/10];
      delay(3);
      P1 = 5;
      P0 = ~Display[Num%1000/100];
      delay(3);
      P1 = 4;
      P0 = ~Display[Num%10000/1000];
      delay(3);
      P1 = 3;
      P0 = ~Display[Num%100000/10000];
      delay(3);
      P1 = 2;
      P0 = ~Display[Num%1000000/100000];
      delay(3);
      P1 = 1;
      P0 = ~Display[Num%10000000/1000000];
      delay(3);
      P1 = 0;
      P0 = ~Display[Num%100000000/1000000];
      delay(3);
  }

}
void main()
{
TMOD = 0x50;
  TH1 = 0x00;
  TL1 = 0x00;
  EA = 1;
  ET1 = 1;
  TR1 = 0;
while(1)
{
   Test2();
}
}

只看该作者 · 2015-11-24 20:56

动态显示驱动：数码管动态显示接口是单片机中应用最为广泛的一种显示方式之一，动态驱动是将所有数码管的8个显示笔划"a,b,c,d,e,f,g,dp"的同名端连在一起，另外为每个数码管的公共极COM增加位选通控制电路，位选通由各自独立的I/O线控制，当单片机输出字形码时，所有数码管都接收到相同的字形码，但究竟是那个数码管会显示出字形，取决于单片机对位选通COM端电路的控制，所以我们只要将需要显示的数码管的选通控制打开，该位就显示出字形，没有选通的数码管就不会亮。通过分时轮流控制各个数码管的的COM端，就使各个数码管轮流受控显示，这就是动态驱动。在轮流显示过程中，每位数码管的点亮时间为1～2ms，由于人的视觉暂留现象及发光二极管的余辉效应，尽管实际上各位数码管并非同时点亮，但只要扫描的速度足够快，给人的印象就是一组稳定的显示数据，不会有闪烁感，动态显示的效果和静态显示是一样的，能够节省大量的I/O端口，而且功耗更低。

只看该作者 · 2015-11-24 20:56

在轮流显示过程中，每位数码管的点亮时间为1～2ms，由于人的视觉暂留现象及发光二极管的余辉效应，尽管实际上各位数码管并非同时点亮，但只要扫描的速度足够快，给人的印象就是一组稳定的显示数据，不会有闪烁感，动态显示的效果和静态显示是一样的，能够节省大量的I/O端口，而且功耗更低。

动态扫描显示接口电路及程序

技术新星奖章

湍急之河流

社区建设奖章

经常做客