F2812的复位引脚上有4.4ms的周期性复位信号

各位高手，本人今天在调试2812的时候仿真器一直连不上dsp。检查了晶振，输出波形正常。但是用示波器看复位引脚的波形时发现有个周期为4.4ms的周期性复位信号。电源芯片是用的TI专用的TPS70351，上电次序也应该没有问题，先外围后内核，看了下电源波形，3.3V和1.8V都还比较稳定。焊上去的2812片子是新的，没有写任何程序，一上电就是这种情况。请教各位，这个信号是从哪里来的，如何消除？谢谢！

以前我也遇到过好几片类似情况，也没查出原因。

这个问题真不想再回答了.dsp2812上电默认是开内部看门狗的.  所以上来先关看门狗就好了.
添加DSP281x_CodeStartBranch.asm到工程中.
;//###########################################################################
;//
;// FILE:  DSP281x_CodeStartBranch.asm       
;//
;// TITLE: Branch for redirecting code execution after boot.
;//
;//###########################################################################
;//
;//  Ver | dd mmm yyyy | Who  | Description of changes
;// =====|=============|======|===============================================
;//  1.00| 11 Sep 03   | L.H. | Updated based on D.A source to allow
;//      |             |      | disabling the watchdog before branching to
;//      |             |      | the C init routine.  This is useful if the
;//      |             |      | watchdog is timing out before main() is reached.
;//###########################################################################        

***********************************************************************

WD_DISABLE        .set        1                ;set to 1 to disable WD, else set to 0

    .ref _c_int00

***********************************************************************
* Function: codestart section
*
* Description: Branch to code starting point
***********************************************************************

    .sect "codestart"

code_start:
    .if WD_DISABLE == 1
        LB wd_disable       ;Branch to watchdog disable code
    .else
        LB _c_int00         ;Branch to start of boot.asm in RTS library
    .endif

;end codestart section

***********************************************************************
* Function: wd_disable
*
* Description: Disables the watchdog timer
***********************************************************************
    .if WD_DISABLE == 1

    .text
wd_disable:
    SETC OBJMODE        ;Set OBJMODE for 28x object code
    EALLOW              ;Enable EALLOW protected register access
    MOVZ DP, #7029h>>6  ;Set data page for WDCR register
    MOV @7029h, #0068h  ;Set WDDIS bit in WDCR to disable WD
    EDIS                ;Disable EALLOW protected register access
    LB _c_int00         ;Branch to start of boot.asm in RTS library

    .endif

;end wd_disable

        .end
       
; end of file CodeStartBranch.asm

应该是目标板设置的问题，才连不上仿真板，裸板接上电源会在复位脚上产生很窄的复位信号是看门狗打开的缘故，这是没有关系的，不影响仿真，关掉狗就好了