21ic电子技术开发论坛 › 单片机与嵌入式系统 › 侃单片机论坛 › 新人学习51，该程序不能正常复位，其他程序可以求原因 ...
返回列表 发新帖我要提问

[51单片机] 新人学习51，该程序不能正常复位，其他程序可以求原因

[复制链接]
1576|9
 楼主| 迹水湾 发表于 2015-5-27 20:17 | 显示全部楼层 |阅读模式
ov, 数码, 数码管, se, COM
本帖最后由 迹水湾 于 2015-5-27 21:29 编辑

结果正确就是不能复位，其他的程序都可以复位
;按键控制数码管显示加减
;单片机stc89c52rc         12Mhz
;共阴数码管
;两片74hc573控制8位数码管
SW0        BIT        P1.0                ;定义SW0为按键加
SW1        BIT        P1.1                ;定义SW1为按键-
D_EN        BIT        P1.2        ;定义段码锁存端
W_EN        BIT        P1.3        ;定义位码锁存端
COM        EQU        P0                        ;将P0定义为数据端
SHIWEI        EQU        40H                ;定义十位存到40h
GEWEI        EQU        41H                ;定义个位存到41h
BUFFER        EQU        42H                ;定义缓存区

        ORG        0000H                ;复位初始化地址
        SJMP        START        ;
        ORG        0030H                ;
START:                                ;初始化
        MOV        SP,60H                ;移动堆栈指针
        SETB        SW0                ;按键+置一
        SETB        SW1                ;按键-置一
        SETB        W_EN        ;打开位选使能
        MOV        COM,#0FFH        ;让所有的数码管都不选中
        CLR        W_EN                ;关闭位选使能
        SETB        D_EN        ;打开段选使能
        MOV        COM,#00H        ;熄灭所有的数码管
        CLR        D_EN                ;关闭段选使能
        CLR        BUFFER                ;清空缓冲区
        MOV        DPTR,#TAB        ;让DPTR指向显示表列
        CLR        SHIWEI                ;清空十位
        CLR        GEWEI                ;清空个位

MAIN:                                ;主函数
        CALL        KEYPORT        ;执行按键扫描程序
        CALL        SHOW        ;执行显示程序
        SJMP        MAIN        ;形成主循环

KEYPORT:                                ;按键子程序
                CALL        DELAY10_MS        ;延时10ms跳过按键抖动区
                JNB        SW0,JIA                        ;判断按键+是否按下，按下执行加法程序
                JNB        SW1,JIAN                ;判断按键-是否按下，按下执行减法程序
        HUI:RET                                        ;若未按下返回主循环
        JIA:                                        ;加法程序
                JNB        SW0,$                        ;判断按键是否释放，未释放pc指针不变
                INC        BUFFER                        ;缓冲区数据加1
                SJMP        HUI                        ;返回主程序
        JIAN:                                        ;减法程序
                JNB        SW1,$                        ;缓冲区数据
                DEC        BUFFER                        ;缓冲区数据减1
                SJMP        HUI                        ;返回主程序

SHOW:                                        ;显示子程序
        MOV        A,BUFFER                ;将缓冲区数据给累加器a
        MOV        B,#10                        ;给寄存器b赋值10
        DIV        AB                                ;执行A/b，结果商（十位）自动存到A，余数（个位）存到b
        MOV        SHIWEI,A                ;将累加器a的十位保存
        MOV        GEWEI,B                        ;将寄存器b中的个位保存
                                                ;显示十位
        MOV        A,SHIWEI                ;将十位的数据给a
        MOVC        A,@A+DPTR        ;将A+DPTR的结果作为地址找到显示的数据
        SETB        W_EN                ;打开位锁存
        MOV        COM,#0FEH                ;设定显示位
        CLR        W_EN                        ;关闭位锁存
        SETB        D_EN                ;打开段锁存
        MOV        COM,A                        ;将显示数据给数码管显示
        CLR                D_EN                ;关闭段锁存
        CALL        DELAY_US        ;延时显示
        SETB        D_EN                ;打开段锁存
        MOV        COM,#00H                ;熄灭数码管，消影
        CLR        D_EN                        ;关闭段锁存
                                                ;显示个位
        MOV        A,GEWEI                        ;将个位数据给a
        MOVC        A,@A+DPTR        ;将a+DPTR作为地址找到显示数据
        SETB        W_EN                ;打开位锁存
        MOV        COM,#0FDH                ;设定显示位
        CLR        W_EN                        ;关闭位锁存
        SETB        D_EN                ;打开段锁存
        MOV        COM,A                        ;将个位数据送到数码管显示
        CLR                D_EN                ;关闭段锁存
        CALL        DELAY_US        ;延时显示
        SETB        D_EN                ;打开段锁存
        MOV        COM,#00H                ;熄灭数码管
        CLR        D_EN                        ;关闭段锁存
        RET                                        ;返回主程序

DELAY10_MS:                        ;延时大约10ms，跳过按键抖动区
        MOV        R7,#50                ;给外层循环赋值50
        D0:        
        MOV        R6,#100                ;给内层循环赋值100
        DJNZ        R6,$        ;R6-- != 0，PC指针不变
        DJNZ        R7,D0        ;R7-- != 0,        再次进入内层循环
        RET                                ;延时子程序返回按键子程序

DELAY_US:                        ;设定数码管显示时间
        MOV        R7,#6                ;给外层循环赋值6
        D1:        
        MOV        R6,#100                ;给内层循环赋值100
        DJNZ        R6,$        ;6-- != 0，PC指针不变
        DJNZ        R7,D1        ;R7-- != 0,        再次进入内层循环
        RET                                ;返回显示子程序


TAB:                                ;共阴数码管显示表列0->9
        DB        03fH,006H,05bH,04fH,066H
        DB        06dH,07dH,007H,07fH,06fH

        END                                ;汇编结束

回复

收藏 举报

相关帖子
 楼主| 迹水湾 发表于 2015-5-27 20:21 | 显示全部楼层
在加减过后数码管的显示不变，并且还能在加减，说明42h单元复位保持就是复位pc指针没有跳到0000h单元
其他的程序都能够复位
回复

收藏 举报

 楼主| 迹水湾 发表于 2015-5-27 20:28 | 显示全部楼层
本帖最后由 迹水湾 于 2015-5-27 21:30 编辑

找不到原因
回复

收藏 举报

 楼主| 迹水湾 发表于 2015-5-27 20:30 | 显示全部楼层
复制
  1. ;按键控制数码管显示加减
    

  2. ;单片机stc89c52rc         12Mhz
    

  3. ;共阴数码管
    

  4. ;两片74hc573控制8位数码管
    

  5. SW0        BIT        P1.0                ;定义SW0为按键加
    

  6. SW1        BIT        P1.1                ;定义SW1为按键-
    

  7. D_EN        BIT        P1.2        ;定义段码锁存端
    

  8. W_EN        BIT        P1.3        ;定义位码锁存端
    

  9. COM        EQU        P0                        ;将P0定义为数据端
    

  10. SHIWEI        EQU        40H                ;定义十位存到40h
    

  11. GEWEI        EQU        41H                ;定义个位存到41h
    

  12. BUFFER        EQU        42H                ;定义缓存区
    

  13.         
    

  14.         ORG        0000H                ;复位初始化地址
    

  15.         SJMP        START        ;
    

  16.         ORG        0030H                ;
    

  17. START:                                ;初始化
    

  18.         MOV        SP,60H                ;移动堆栈指针
    

  19.         SETB        SW0                ;按键+置一
    

  20.         SETB        SW1                ;按键-置一
    

  21.         SETB        W_EN        ;打开位选使能
    

  22.         MOV        COM,#0FFH        ;让所有的数码管都不选中
    

  23.         CLR        W_EN                ;关闭位选使能
    

  24.         SETB        D_EN        ;打开段选使能
    

  25.         MOV        COM,#00H        ;熄灭所有的数码管
    

  26.         CLR        D_EN                ;关闭段选使能
    

  27.         CLR        BUFFER                ;清空缓冲区
    

  28.         MOV        DPTR,#TAB        ;让DPTR指向显示表列
    

  29.         CLR        SHIWEI                ;清空十位
    

  30.         CLR        GEWEI                ;清空个位
    


  31. 

  32. MAIN:                                ;主函数
    

  33.         CALL        KEYPORT        ;执行按键扫描程序
    

  34.         CALL        SHOW        ;执行显示程序
    

  35.         SJMP        MAIN        ;形成主循环
    


  36. 

  37. KEYPORT:                                ;按键子程序
    

  38.                 CALL        DELAY10_MS        ;延时10ms跳过按键抖动区
    

  39.                 JNB        SW0,JIA                        ;判断按键+是否按下，按下执行加法程序
    

  40.                 JNB        SW1,JIAN                ;判断按键-是否按下，按下执行减法程序
    

  41.         HUI:RET                                        ;若未按下返回主循环
    

  42.         JIA:                                        ;加法程序
    

  43.                 JNB        SW0,$                        ;判断按键是否释放，未释放pc指针不变
    

  44.                 INC        BUFFER                        ;缓冲区数据加1
    

  45.                 SJMP        HUI                        ;返回主程序
    

  46.         JIAN:                                        ;减法程序
    

  47.                 JNB        SW1,$                        ;缓冲区数据
    

  48.                 DEC        BUFFER                        ;缓冲区数据减1
    

  49.                 SJMP        HUI                        ;返回主程序
    


  50. 

  51. SHOW:                                        ;显示子程序
    

  52.         MOV        A,BUFFER                ;将缓冲区数据给累加器a
    

  53.         MOV        B,#10                        ;给寄存器b赋值10
    

  54.         DIV        AB                                ;执行A/b，结果商（十位）自动存到A，余数（个位）存到b
    

  55.         MOV        SHIWEI,A                ;将累加器a的十位保存
    

  56.         MOV        GEWEI,B                        ;将寄存器b中的个位保存
    

  57.                                                 ;显示十位
    

  58.         MOV        A,SHIWEI                ;将十位的数据给a
    

  59.         MOVC        A,@A+DPTR        ;将A+DPTR的结果作为地址找到显示的数据
    

  60.         SETB        W_EN                ;打开位锁存
    

  61.         MOV        COM,#0FEH                ;设定显示位
    

  62.         CLR        W_EN                        ;关闭位锁存
    

  63.         SETB        D_EN                ;打开段锁存
    

  64.         MOV        COM,A                        ;将显示数据给数码管显示
    

  65.         CLR                D_EN                ;关闭段锁存
    

  66.         CALL        DELAY_US        ;延时显示
    

  67.         SETB        D_EN                ;打开段锁存
    

  68.         MOV        COM,#00H                ;熄灭数码管，消影
    

  69.         CLR        D_EN                        ;关闭段锁存
    

  70.                                                 ;显示个位
    

  71.         MOV        A,GEWEI                        ;将个位数据给a
    

  72.         MOVC        A,@A+DPTR        ;将a+DPTR作为地址找到显示数据
    

  73.         SETB        W_EN                ;打开位锁存
    

  74.         MOV        COM,#0FDH                ;设定显示位
    

  75.         CLR        W_EN                        ;关闭位锁存
    

  76.         SETB        D_EN                ;打开段锁存
    

  77.         MOV        COM,A                        ;将个位数据送到数码管显示
    

  78.         CLR                D_EN                ;关闭段锁存
    

  79.         CALL        DELAY_US        ;延时显示
    

  80.         SETB        D_EN                ;打开段锁存
    

  81.         MOV        COM,#00H                ;熄灭数码管
    

  82.         CLR        D_EN                        ;关闭段锁存
    

  83.         RET                                        ;返回主程序
    


  84. 

  85. DELAY10_MS:                        ;延时大约10ms，跳过按键抖动区
    

  86.         MOV        R7,#50                ;给外层循环赋值50
    

  87.         D0:        
    

  88.         MOV        R6,#100                ;给内层循环赋值100
    

  89.         DJNZ        R6,$        ;R6-- != 0，PC指针不变
    

  90.         DJNZ        R7,D0        ;R7-- != 0,        再次进入内层循环
    

  91.         RET                                ;延时子程序返回按键子程序
    


  92. 

  93. DELAY_US:                        ;设定数码管显示时间
    

  94.         MOV        R7,#6                ;给外层循环赋值6
    

  95.         D1:        
    

  96.         MOV        R6,#100                ;给内层循环赋值100
    

  97.         DJNZ        R6,$        ;6-- != 0，PC指针不变
    

  98.         DJNZ        R7,D1        ;R7-- != 0,        再次进入内层循环
    

  99.         RET                                ;返回显示子程序
    


  100. 


  101. 

  102. TAB:                                ;共阴数码管显示表列0->9
    

  103.         DB        03fH,006H,05bH,04fH,066H
    

  104.         DB        06dH,07dH,007H,07fH,06fH
    


  105. 

  106.         END                                ;汇编结束
    

  107.                
回复

收藏 举报

cuya 发表于 2015-5-27 21:04 | 显示全部楼层
我会非常非常佩服那个能仔细阅读你的汇编程序并指出错误的人。
回复

收藏 举报

 楼主| 迹水湾 发表于 2015-5-27 21:24 | 显示全部楼层
cuya 发表于 2015-5-27 21:04
我会非常非常佩服那个能仔细阅读你的汇编程序并指出错误的人。

木有人回复，软件仿真可以，为什么事实就是可以运行，结果也正确，就是不能复位不能成功
回复

收藏 举报

 楼主| 迹水湾 发表于 2015-5-27 21:27 | 显示全部楼层
cuya 发表于 2015-5-27 21:04
我会非常非常佩服那个能仔细阅读你的汇编程序并指出错误的人。

之前是copy的贴吧里的发表，它缺掉了制表符
回复

收藏 举报

lyjian 发表于 2015-5-27 22:15 | 显示全部楼层
CLR是位操作指令，不是字节操作指令。
CLR        BUFFER                ;清空缓冲区
CLR        SHIWEI                ;清空十位
CLR        GEWEI    
这几条都是错的
回复

收藏 举报

lyjian 发表于 2015-5-27 22:22 | 显示全部楼层
改成：
CLR        A
MOV       BUFFER,A             ;清空缓冲区
MOV       SHIWEI,A              ;清空十位
MOV       GEWEI,A  
回复

收藏 举报

 楼主| 迹水湾 发表于 2015-5-27 22:34 | 显示全部楼层
对只能clr A和bit非常感谢上面那位大神
回复

收藏 举报

返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册

本版积分规则

迹水湾

18

主题

44

帖子

1

粉丝
快速回复 在线客服 返回列表 返回顶部