搜索
发新帖本帖赏金 100.00元(功能说明)我要提问
返回列表

[ARM入门] ESP8266还是连不上小爱同学和天猫精灵?试试点灯科技blinker!

[复制链接]
12750|1
呐咯密密|  楼主 | 2021-5-21 00:21 | 显示全部楼层 |阅读模式
本帖最后由 呐咯密密 于 2021-5-21 00:23 编辑

申请原创# @21小跑堂
@21小跑堂
本文主要内容:ESP8266手机APP控制WS2812实现炫彩LED灯;
                      ESP8266连接小爱同学,实现手机语音控制设备;
                       ESP8266连接天猫精灵,实现低成本的智能家居体验。
人类的这颗躁动的心,只要冲动一次,热血便难凉。。。。。。
从接触ESP8266开始,家里的一切设备我就都想换一个方式控制,说到底就是懒了,不然也不会这么胖。当冲动的将天猫精灵拿到手后,那种开发的冲动便一发不可收拾。于是当时跟着徐宏大佬用安信可的环境开发了ESP8266+天猫精灵的智能灯和智能插座,同时具备零配功能,直接“天猫精灵,找队友”,便可让设备入网。但是换工作后不用ESP8266,后来该设计也没有继续深入研究。最近为了混点原创,就想着把之前的天猫精灵项目拿出来分享一下。结果发现阿里物联网平台的设备都迁移到飞燕平台了,好多东西都变了,搞得我都看不懂了。而且开发环境特别乱,特别难搭建,一不小心就会出错。干脆放弃造轮子,换到了无敌香的点灯科技,使用Arduino,开发难度小,适合新手入门。本文将从头开始教你如何将ESP8266接入小爱同学和天猫精灵,当然,小度也是可以的,但是本人无此设备,不演示。
一、搭建环境
1.材料准备:ESP8266(本人使用nodeMCU ESP8266),ArduinoIDE,esp8266扩展
ESP8266自行购买,ArduinoIDE下载链接:官方链接腾讯云。ESP8266扩展:微云
ArduinoIDE傻瓜安装,安装过程会安装驱动,同意便好,该过程出现问题直接找战略合作伙伴ESP8266的扩展文件下载后直接运行便可。
2.安装blinke APP,小米应用商店没有,建议直接去百度下载,或者提供我的微云链接
3.[color=rgba(0, 0, 0, 0.85)]下载并安装blinker Arduino库,该库直接在ArduinoIDE中下载便好,可能会有点慢,方法:打开ArduinoIDE,顶部导航栏->项目->加载库->管理库。在搜索框中搜索[color=rgba(0, 0, 0, 0.85)]blinker,点击安装便可。安装完关闭。
3901460a67d99710c7.png
或者按照以下链接下载链接将下载好的blinker库解压到 我的电脑>文档>Arduino>libraries 文件夹中
至此 ,环境搭建完成,开始造作吧!
二、测试环境,点灯。
将ESP8266连接电脑,因为我是用的是nodeMCU,直接用一根USB线连接电脑便可,打开ArduinoIDE,顶部菜单栏>工具>开发板 中找到你使用的esp8266开发板,这边即使是使用nodeMCU,也不要选择这个选项,选择Generic ESP8266 module。
1349460a680a565b3f.png
顶部菜单栏>工具>端口,选择ESP8266占用的端口。     
4473960a68144ae124.png    
顶部菜单栏>文件>示例>01.Basics>Blink.打开示例代码,该代码仅仅控制一个LED闪烁,LED_BUILTIN为开发板厂商定义的LED引脚,可自行修改,如改为3,便是GPIO3。
8331260a681c9241da.png 9716360a682f77765f.png
点击上传,开始编译文件并烧录工程,nodeMCU可以直接烧录,如果是自己的模块可能需要短按复位,遇到该问题可留言咨询。
烧录完成后看到LED闪烁说明一切无误。开始我们的无线之旅。
三、连接小爱同学,控制WS2812。
1.打开blinke APP,选择添加设备>独立设备(在老的版本中是选择arduino设备,现在已无该选项)>网络接入>阿里云>复制key
661060a68442233bd.png 3320660a68453da276.png 597960a6846900189.png 966860a6847bc9462.png 9820360a6848ca8cd7.png
此时我们修改我们的Blink代码
  1. //#define BLINKER_ESP_SMARTCONFIG
  2. #define BLINKER_WIFI/////////////////// wifi
  3. #define BLINKER_MIOT_LIGHT ////////////小爱

  4. #include <Blinker.h>

  5. char auth[] = "授权码";//////////手机下载 blinker app 复制的key
  6. char ssid[] = "wifi账号";/////wifi ssid
  7. char pswd[] = "WiFi密码";///wifi 密码
  8. int openState = 0; ///默认为单色模式
  9. // Download Adafruit_NeoPixel library here:
  10. // https://github.com/adafruit/Adafruit_NeoPixel
  11. #include <Adafruit_NeoPixel.h>

  12. #define PIN            3   ////开发板的引脚编号 接WS2812 data  VCC--VCC  GND-GND DATA/DI(DATA INPUT)--17 具体看产品说明
  13. #define NUMPIXELS      24  ////开发板灯灯珠数量 位
  14. Adafruit_NeoPixel pixels = Adafruit_NeoPixel(NUMPIXELS, PIN, NEO_GRB + NEO_KHZ800);
  15. #define BUTTON_1 "ButtonKey"   ///////////////【APP内用来控制呼吸灯开关】app中添加 开关按键 数据键名ButtonKey  一致即可 注意大小写
  16. #define RGB_1 "RGBKey"              ///////////////【APP内用来控制颜色及亮度】app中添加调色盘 数据键名RGBKey  一致即可

  17. BlinkerRGB WS2812(RGB_1);
  18. BlinkerButton Button1(BUTTON_1);
  19. uint8_t colorR, colorG, colorB, colorW;
  20. bool wsState;
  21. uint8_t wsMode = BLINKER_CMD_MIOT_DAY;

  22. void pixelShow()
  23. {
  24.   pixels.setBrightness(colorW);

  25.   for (int i = 0; i < NUMPIXELS; i++) {
  26.     pixels.setPixelColor(i, colorR, colorG, colorB);
  27.   }
  28.   pixels.show();
  29. }

  30. void ws2812_callback(uint8_t r_value, uint8_t g_value, uint8_t b_value, uint8_t bright_value)
  31. {
  32.   digitalWrite(LED_BUILTIN, !digitalRead(LED_BUILTIN));
  33.   openState = 0;
  34.   Button1.print("off");
  35.   BLINKER_LOG("R value: ", r_value);
  36.   BLINKER_LOG("G value: ", g_value);
  37.   BLINKER_LOG("B value: ", b_value);
  38.   BLINKER_LOG("Rrightness value: ", bright_value);

  39.   colorR = r_value;
  40.   colorG = g_value;
  41.   colorB = b_value;
  42.   colorW = bright_value;

  43.   pixelShow();
  44. }
  45. void button1_callback(const String & state)
  46. {
  47.   digitalWrite(LED_BUILTIN, !digitalRead(LED_BUILTIN));
  48.   BLINKER_LOG("get button state: ", state);

  49.   if (state == BLINKER_CMD_ON) {
  50.     BLINKER_LOG("Toggle on!");
  51.     Button1.print("on");
  52.     openState = 1;
  53.   }
  54.   else if (state == BLINKER_CMD_OFF) {
  55.     BLINKER_LOG("Toggle off!");
  56.     Button1.print("off");
  57.     openState = 0;
  58.   }

  59. }

  60. uint32_t getColor()
  61. {
  62.   uint32_t color = colorR << 16 | colorG << 8 | colorB;

  63.   return color;
  64. }

  65. void miotPowerState(const String & state)
  66. {
  67.   BLINKER_LOG("need set power state: ", state);

  68.   if (state == BLINKER_CMD_ON) {
  69.     digitalWrite(LED_BUILTIN, HIGH);

  70.     BlinkerMIOT.powerState("on");
  71.     BlinkerMIOT.print();

  72.     wsState =true;

  73.     if (colorW==0) colorW =255;
  74.   }
  75.   else if (state == BLINKER_CMD_OFF) {
  76.     digitalWrite(LED_BUILTIN, HIGH);

  77.     BlinkerMIOT.powerState("off");
  78.     BlinkerMIOT.print();

  79.     wsState = false;
  80.     if (colorW >0) colorW = 0;
  81.   
  82.   }

  83.   pixelShow();
  84. }
  85. ///////////////////////////////////////////////////////呼吸灯
  86. uint32_t Wheel(byte WheelPos) {
  87.   WheelPos = 255 - WheelPos;
  88.   if (WheelPos < 85) {
  89.     return pixels.Color(255 - WheelPos * 3, 0, WheelPos * 3);
  90.   }
  91.   if (WheelPos < 170) {
  92.     WheelPos -= 85;
  93.     return pixels.Color(0, WheelPos * 3, 255 - WheelPos * 3);
  94.   }
  95.   WheelPos -= 170;
  96.   return pixels.Color(WheelPos * 3, 255 - WheelPos * 3, 0);
  97. }

  98. void rainbow(uint8_t wait) {
  99.   uint16_t i, j;

  100.   for (j = 0; j < 256; j++) {
  101.     for (i = 0; i < pixels.numPixels(); i++) {
  102.       //time_show();
  103.       // dhtShow();
  104.       pixels.setPixelColor(i, Wheel((i + j) & 255));
  105.     }
  106.     pixels.show();
  107.     delay(wait);
  108.   }
  109. }


  110. void miotColor(int32_t color)
  111. {
  112.   BLINKER_LOG("need set color: ", color);

  113.   colorR = color >> 16 & 0xFF;
  114.   colorG = color >>  8 & 0xFF;
  115.   colorB = color       & 0xFF;

  116.   BLINKER_LOG("colorR: ", colorR, ", colorG: ", colorG, ", colorB: ", colorB);

  117.   pixelShow();

  118.   BlinkerMIOT.color(color);
  119.   BlinkerMIOT.print();
  120. }

  121. void miotMode(uint8_t mode)
  122. {
  123.   BLINKER_LOG("need set mode: ", mode);

  124.   if (mode == BLINKER_CMD_MIOT_DAY) {
  125.     //日光模式   小爱同学的语音命令 模式中文名称参考 https://www.diandeng.tech/doc/xiaoai
  126.   }
  127.   else if (mode == BLINKER_CMD_MIOT_NIGHT) {
  128.     // Your mode function
  129.   }
  130.   else if (mode == BLINKER_CMD_MIOT_COLOR) {
  131.     // Your mode function
  132.     openState = 0;
  133.   }
  134.   else if (mode == BLINKER_CMD_MIOT_WARMTH) {
  135.     // Your mode function
  136.   }
  137.   else if (mode == BLINKER_CMD_MIOT_TV) {
  138.     // Your mode function
  139.   }
  140.   else if (mode == BLINKER_CMD_MIOT_READING) {
  141.     // Your mode function
  142.   }
  143.   else if (mode == BLINKER_CMD_MIOT_COMPUTER) {
  144.     // 电脑模式
  145.     openState = 1;
  146.   }

  147.   wsMode = mode;

  148.   BlinkerMIOT.mode(mode);
  149.   BlinkerMIOT.print();
  150. }

  151. void miotBright(const String & bright)
  152. {
  153.   BLINKER_LOG("need set brightness: ", bright);

  154.   colorW = bright.toInt();

  155.   BLINKER_LOG("now set brightness: ", colorW);

  156.   pixelShow();

  157.   BlinkerMIOT.brightness(colorW);
  158.   BlinkerMIOT.print();
  159. }

  160. void miotColoTemp(int32_t colorTemp)
  161. {
  162.   BLINKER_LOG("need set colorTemperature: ", colorTemp);

  163.   BlinkerMIOT.colorTemp(colorTemp);
  164.   BlinkerMIOT.print();
  165. }

  166. void miotQuery(int32_t queryCode)
  167. {
  168.   BLINKER_LOG("MIOT Query codes: ", queryCode);

  169.   switch (queryCode)
  170.   {
  171.     case BLINKER_CMD_QUERY_ALL_NUMBER :
  172.       BLINKER_LOG("MIOT Query All");
  173.       BlinkerMIOT.powerState(wsState ? "on" : "off");
  174.       BlinkerMIOT.color(0);
  175.       BlinkerMIOT.mode(0);
  176.       BlinkerMIOT.colorTemp(1000);
  177.       BlinkerMIOT.brightness(1);
  178.       BlinkerMIOT.print();
  179.       break;
  180.     case BLINKER_CMD_QUERY_POWERSTATE_NUMBER :
  181.       BLINKER_LOG("MIOT Query Power State");
  182.       BlinkerMIOT.powerState(wsState ? "on" : "off");
  183.       BlinkerMIOT.print();
  184.       break;
  185.     case BLINKER_CMD_QUERY_COLOR_NUMBER :
  186.       BLINKER_LOG("MIOT Query Color");
  187.       BlinkerMIOT.color(0);
  188.       BlinkerMIOT.print();
  189.       break;
  190.     case BLINKER_CMD_QUERY_MODE_NUMBER :
  191.       BLINKER_LOG("MIOT Query Mode");
  192.       BlinkerMIOT.mode(0);
  193.       BlinkerMIOT.print();
  194.       break;
  195.     case BLINKER_CMD_QUERY_COLORTEMP_NUMBER :
  196.       BLINKER_LOG("MIOT Query ColorTemperature");
  197.       BlinkerMIOT.colorTemp(1000);
  198.       BlinkerMIOT.print();
  199.       break;
  200.     case BLINKER_CMD_QUERY_BRIGHTNESS_NUMBER :
  201.       BLINKER_LOG("MIOT Query Brightness");
  202.       BlinkerMIOT.brightness(1);
  203.       BlinkerMIOT.print();
  204.       break;
  205.     default :
  206.       BlinkerMIOT.powerState(wsState ? "on" : "off");
  207.       BlinkerMIOT.color(0);
  208.       BlinkerMIOT.mode(0);
  209.       BlinkerMIOT.colorTemp(1000);
  210.       BlinkerMIOT.brightness(1);
  211.       BlinkerMIOT.print();
  212.       break;
  213.   }
  214. }

  215. void dataRead(const String & data)
  216. {
  217.   BLINKER_LOG("Blinker readString: ", data);

  218.   Blinker.vibrate();

  219.   uint32_t BlinkerTime = millis();

  220.   Blinker.print("millis", BlinkerTime);
  221. }

  222. void setup()
  223. {
  224.   Serial.begin(115200);
  225.   BLINKER_DEBUG.stream(Serial);
  226.   BLINKER_DEBUG.debugAll();
  227. //   Blinker.begin(auth);                        //必须有这句,配置网络必备
  228.   pinMode(LED_BUILTIN, OUTPUT);
  229.   digitalWrite(LED_BUILTIN, LOW);

  230.   Blinker.begin(auth, ssid, pswd);

  231.   Blinker.attachData(dataRead);

  232.   BlinkerMIOT.attachPowerState(miotPowerState);
  233.   BlinkerMIOT.attachColor(miotColor);
  234.   BlinkerMIOT.attachMode(miotMode);
  235.   BlinkerMIOT.attachBrightness(miotBright);
  236.   BlinkerMIOT.attachColorTemperature(miotColoTemp);
  237.   BlinkerMIOT.attachQuery(miotQuery);

  238.   pinMode(14, OUTPUT);
  239.   digitalWrite(14, HIGH);
  240.   pinMode(15, OUTPUT);
  241.   digitalWrite(15, HIGH);

  242.   colorR = 255;
  243.   colorG = 255;
  244.   colorB = 255;
  245.   colorW = 0;
  246.   wsState = true;
  247.   

  248.   pixels.begin();
  249.   pixels.setBrightness(colorW);
  250.   WS2812.attach(ws2812_callback);
  251.   Button1.attach(button1_callback);
  252.   pixelShow();
  253. }

  254. void loop()
  255. {
  256.   Blinker.run();
  257.   if (openState == 0)
  258.   {
  259.     pixelShow();
  260.     //Button1.print("off");

  261.   }
  262.   else if (openState == 1)
  263.   {
  264.     rainbow(15);/////////15呼吸灯的频率
  265.     //Button1.print("on");
  266.   }
  267. }
复制代码
将上面的代码直接覆盖源代码,修改这几个参数便可
2195660a687ee2803f.png
修改引脚和WS2812的灯珠数量。
2255860a685d2d75a0.png
注意WiFi必须是2.4G频段,5G频段不可使用。修改完成后上传代码到ESP8266。
此时打开“点灯-blinker”APP,
8268960a686a4e8091.png
可以看到有自己的设备,点进去可以看到设备状态,是否在线,如果一切顺利,此时应该能看到设备处于在线状态
那么现在我们就要将这个设备添加进小爱同学。
打开米家APP,在我的>其他平台设备>添加>点灯科技,绑定账号后就会将我们之前的设备添加到米家,就可以通过小爱同学进行控制了。
1305460a6890d94173.png
1621527568743.gif

到此就完成啦,当然这里面还有很多瑕疵,后面会追加使用天猫精灵控制,而且使用手机配网,而不是写在固件中。时间问题,今天到此为止,后期开发敬请期待。

使用特权

评论回复

打赏榜单

21小跑堂 打赏了 100.00 元 2021-05-21
理由:恭喜通过原创奖文章审核!请多多加油哦!

相关帖子

GlenX| | 2021-5-28 12:02 | 显示全部楼层
看了几遍,看来还得学习!

使用特权

评论回复
扫描二维码,随时随地手机跟帖
返回列表 发新帖 本帖赏金 100.00元(功能说明)我要提问
您需要登录后才可以回帖 登录 | 注册

本版积分规则

我要发帖 我要提问 投诉建议 申请版主

快速回复

您需要登录后才可以回帖
登录 | 注册
高级模式

本版热帖

本版活跃用户

优质原创写原创,赢大奖

编辑推荐

  • 1 wolfe_yu 得到打赏 ¥180.00
  • 2 最美葫芦娃 得到打赏 ¥155.00
  • 3 hk386 得到打赏 ¥75.00
  • 4 火星国务卿 得到打赏 ¥63.00
  • 5 两只袜子 得到打赏 ¥56.00
  • 6 laocuo1142 得到打赏 ¥50.00
  • 7 ezcui 得到打赏 ¥45.00
  • 8 linghz 得到打赏 ¥45.00
  • 9 gaon2 得到打赏 ¥45.00
  • 10 liang-1011 得到打赏 ¥40.00
在线客服 快速回复 返回顶部 返回列表