89C2051带音乐的电子闹钟(已测试OK)

只看该作者 · 2008-6-1 22:22

不知道为什么发不了图，PCB图大家可以去http://www.cnieee.com搜下

原理图,可以点击放大!!
//*APPLICATION NOTE  E6000 ICEXPLORER ***************
//* Title:           FOR AT89C2051时钟程序          *
//* Version:         00                             *
//* Last Updated:                                   *
//* MCU:             AT89C2051                      *
//* FOR:             WWW.cnieee.COM                 *
//***************************************************
;  定时器T0、T1溢出周期为50MS，T0为秒计数用， T1为调整时闪烁用，
;  P3.7为调整按钮，P1口为字符输出口，采用共阳显示管。
;**************************************************************
                C_HOUR      EQU    30H         ;当前时的个位地址定义
                C_MINUTE    EQU    31H         ;当前分的个位地址定义
                ON_HOUR     EQU    32H         ;开机时的个位地址定义
                ON_MINUTE   EQU    33H         ;开机分的个位地址定义
                OFF_HOUR    EQU    34H         ;关机时的个位地址定义
                OFF_MINUTE  EQU    35H         ;关机分的个位地址定义
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;           中断入口程序              ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
                ORG     0000H                ;程序执行开始地址
                LJMP    START                ;跳到标号START执行
                ORG     0003H                ;外中断0中断程序入口
                RETI                         ;外中断0中断返回
                ORG     000BH                ;定时器T0中断程序入口
                LJMP    INTT0                ;跳至INTTO执行
                ORG     0013H                ;外中断1中断程序入口
                RETI                         ;外中断1中断返回
                ORG     001BH                ;定时器T1中断程序入口
                LJMP    INTT1                ;跳至INTT1执行
                ORG     0023H                ;串行中断程序入口地址
                RETI                         ;串行中断程序返回
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;           主程序                 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
                   ORG   0030H
START:             MOV   SP,#50H             ;堆栈指针入口地址
                   CLR   P1.7
                   ANL   P1,#0FFH
                   MOV   C_HOUR,#00H
                   MOV   C_MINUTE,#00H
;********************************************************************
                   MOV   ON_HOUR,#08H
                   MOV   ON_MINUTE,#00H    ;置开机时间为08:00
                   MOV   OFF_HOUR,#08H
                   MOV   OFF_MINUTE,#01H   ;置关机时间为08:01
;********************************************************************
                   MOV   R0,#70H        ;清70H-7AH共11个内存单元
                   MOV   R7,#0BH        ;
CLEARDISP:         MOV   @R0,#00H        ;
                   INC   R0                ;
                   DJNZ  R7,CLEARDISP      ;
                   MOV   20H,#00H       ;清20H（标志用）
                   MOV   7AH,#0AH          ;放入"熄灭符"数据
                   MOV   TMOD,#11H         ;设T0、T1为16位定时器
                   MOV   TL0,#0B0H     ;50MS定时初值（T0计时用）
                   MOV   TH0,#3CH     ;50MS定时初值
                   MOV   TL1,#0B0H     ;50MS定时初值（T1闪烁定时用）
                   MOV   TH1,#3CH      ;50MS定时初值
                   SETB  EA                ;总中断开放
                   SETB  ET0               ;允许T0中断
                   SETB  TR0               ;开启T0定时器
                   MOV   R4,#14H           ;1秒定时用初值（50MS×20）
LOOP:              MOV   A,C_HOUR
                   CJNE  A,ON_HOUR,OFF_TIME
                   MOV   A,C_MINUTE
                   CJNE  A,ON_MINUTE,OFF_TIME ;判断当前时间是否等於开机时间
                   SETB  P1.7                  ;置开关输出控制端口P3.7为"0"
                   AJMP  START1

OFF_TIME:          MOV   A,C_HOUR
                   CJNE  A,OFF_HOUR,START1
                   MOV   A,C_MINUTE
                   CJNE  A,OFF_MINUTE,START1 ;判断当前时间是否等於关机时间
                   CLR   P1.7                ;置开关输出控制端口P3.7为"1"

START1:            LCALL DISPLAY             ;调用显示子程序
                   JNB   P3.7,SETMM1         ;P3.7口为0时转时间调整程序
                   SJMP  LOOP                ;P3.7口为1时跳回START1
SETMM1:            LJMP  SETMM               ;转到时间调整程序SETMM
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;           1秒计时程序              ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;T0中断服务程序
INTT0:             PUSH  ACC               ;累加器入栈保护
                   PUSH  PSW               ;状态字入栈保护
                   CLR   ET0               ;关T0中断允许
                   CLR   TR0               ;关闭定时器T0
                   MOV   A,#0B7H           ;中断响应时间同步修正
                   ADD   A,TL0             ;低8位初值修正
                   MOV   TL0,A             ;重装初值（低8位修正值）
                   MOV   A,#3CH            ;高8位初值修正
                   ADDC  A,TH0             ;
                   MOV   TH0,A             ;重装初值（高8位修正值）
                   SETB  TR0               ;开启定时器T0
                   DJNZ  R4, OUTT0         ;20次中断未到中断退出
           ADDSS:  MOV  R4,#14H           ;20次中断到（1秒）重赋初值
                   MOV   R0,#71H           ;指向秒计时单元（71H-72H）
                   ACALL ADD1              ;调用加1程序（加1秒操作）
                   MOV   A,R3              ;秒数据放入A（R3为2位十进制数组合）
                   CLR  C                 ;清进位标志
                   CJNE  A,#60H,ADDMM      ;
           ADDMM:  JC    OUTT0             ;小于60秒时中断退出
                   ACALL CLR0              ;大于或等于60秒时对秒计时单元清0
                   MOV  R0,#77H           ;指向分计时单元（76H-77H）
                   ACALL ADD1              ;分计时单元加1分钟
                   MOV   A,R3              ;分数据放入A
                   MOV   C_MINUTE,A
                   CLR   C                 ;清进位标志
                   CJNE  A,#60H,ADDHH      ;
            ADDHH: JC  OUTT0             ;小于60分时中断退出
                   MOV   C_MINUTE,#00H
                   ACALL CLR0              ;大于或等于60分时分计时单元清0
                   MOV  R0,#79H           ;指向小时计时单元（78H-79H）
                   ACALL ADD1              ;小时计时单元加1小时
                   MOV   A,R3              ;时数据放入A
                   MOV   C_HOUR,A
                   CLR   C                 ;清进位标志
                   CJNE  A,#24H,HOUR       ;
             HOUR: JC    OUTT0             ;小于24小时中断退出
                   MOV   C_HOUR,#00H
                   ACALL CLR0              ;大于或等于24小时小时计时单元清0
            OUTT0: MOV   72H,76H           ;中断退出时将分、时计时单元数据移
                   MOV   73H,77H           ;入对应显示单元
                   MOV   74H,78H           ;
                   MOV   75H,79H           ;
                   POP   PSW               ;恢复状态字（出栈）
                   POP   ACC               ;恢复累加器
                   SETB  ET0               ;开放T0中断
                   RETI                    ;中断返回
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;           闪动调时程序            ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;T1中断服务程序，用作时间调整时调整单元闪烁指示
INTT1:          PUSH    ACC                ;中断现场保护
                PUSH    PSW                ;
                MOV     TL1,   #0B0H       ;装定时器T1定时初值
                MOV     TH1,   #3CH        ;
                DJNZ    R2,INTT1OUT        ;0.3秒未到退出中断（50MS中断6次）
                MOV     R2,#06H            ;重装0.3秒定时用初值
                CPL     02H                ;0.3秒定时到对闪烁标志取反
                JB      02H,FLASH1         ;02H位为1时显示单元"熄灭"
                MOV     72H,76H            ;02H位为0时正常显示
                MOV     73H,77H            ;
                MOV     74H,78H            ;
                MOV     75H,79H            ;
INTT1OUT:       POP     PSW           ;恢复现场
                POP     ACC                ;
                RETI                       ;中断退出
FLASH1:         JB      01H,FLASH2         ;01H位为1时，转小时熄灭控制
                MOV     72H,7AH            ;01H位为0时，"熄灭符"数据放入分
                MOV     73H,7AH            ;显示单元（72H-73H），将不显示分数据
                MOV     74H,78H            ;
                MOV     75H,79H            ;
                AJMP    INTT1OUT           ;转中断退出
FLASH2:         MOV     72H,76H            ;01H位为1时，"熄灭符"数据放入小时
                MOV     73H,77H            ;显示单元（74H-75H），小时数据将不显示
                MOV     74H,7AH            ;
                MOV     75H,7AH            ;
                AJMP    INTT1OUT           ;转中断退出

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;           加1子程序              ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

             ADD1: MOV  A,@R0             ;取当前计时单元数据到A
                   DEC  R0                ;指向前一地址
                   SWAP  A                 ;A中数据高四位与低四位交换
                   ORL   A,@R0             ;前一地址中数据放入A中低四位
                   ADD  A,#01H            ;A加1操作
                   DA   A                 ;十进制调整
                   MOV   R3,A              ;移入R3寄存器
                   ANL   A,#0FH            ;高四位变0
                   MOV   @R0,A             ;放回前一地址单元
                   MOV  A,R3              ;取回R3中暂存数据
                   INC  R0                ;指向当前地址单元
                   SWAP  A                 ;A中数据高四位与低四位交换
                   ANL   A,#0FH            ;高四位变0
                   MOV  @R0,A             ;数据放入当削地址单元中
                   RET                     ;子程序返回

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;           清零程序                  ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;对计时单元复零用
             CLR0: CLR   A            ;清累加器
                   MOV   @R0,A        ;清当前地址单元
                   DEC   R0           ;指向前一地址
                   MOV   @R0,A        ;前一地址单元清0
                   RET                     ;子程序返回
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;           时钟调整程序              ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;当调时按键按下时进入此程序
           SETMM:  CLR   ET0            ;关定时器T0中断
                   CLR   TR0            ;关闭定时器T0
                   LCALL   DL1S           ;调用1秒延时程序
                   JB    P3.7,CLOSEDIS  ;键按下时间小于1秒，关闭显示（省电）
                   MOV   R2,#06H        ;进入调时状态，赋闪烁定时初值
                   SETB  ET1            ;允许T1中断
                   SETB  TR1            ;开启定时器T1
            SET2:  JNB   P3.7,SET1      ;P3.7口为0（键未释放），等待
                   SETB   00H            ;键释放，分调整闪烁标志置1
            SET4:  JB    P3.7,SET3      ;等待键按下
                   LCALL    DL05S          ;有键按下，延时0.5秒
                   JNB     P3.7,SETHH     ;按下时间大于0.5秒转调小时状态
                   MOV   R0,#77H        ;按下时间小于0.5秒加1分钟操作
                   LCALL  ADD1           ;调用加1子程序
                   MOV   A,R3           ;取调整单元数据
                   CLR   C              ;清进位标志
                   CJNE  A,#60H,HHH     ;调整单元数据与60比较
              HHH: JC   SET4           ;调整单元数据小于60转SET4循环
                   LCALL  CLR0           ;调整单元数据大于或等于60时清0
                   CLR   C              ;清进位标志
                   AJMP   SET4           ;跳转到SET4循环
        CLOSEDIS:  SETB  ET0            ;省电（LED不显示）状态。开T0中断
                   SETB  TR0            ;开启T0定时器（开时钟）
        CLOSE:     JB    P3.7,CLOSE     ;无按键按下，等待。
                   LCALL DISPLAY        ;有键按下，调显示子程序延时削抖
                   JB     P3.7,CLOSE     ;是干扰返回CLOSE等待
        WAITH:     JNB    P3.7,WAITH     ;等待键释放
                   LJMP   START1         ;返回主程序（LED数据显示亮）
           SETHH:  CLR        00H            ;分闪烁标志清除（进入调小时状态）
          SETHH1:  JNB   P3.7,SET5      ;等待键释放
                   SETB       01H            ;小时调整标志置1
            SET6:  JB    P3.7,SET7      ;等待按键按下
                   LCALL    DL05S          ;有键按下延时0.5秒
                   JNB     P3.7,SETOUT    ;按下时间大于0.5秒退出时间调整
                   MOV  R0,#79H        ;按下时间小于0.5秒加1小时操作
                   LCALL  ADD1           ;调加1子程序
                   MOV  A,R3           ;
                   CLR   C              ;
                   CJNE  A,#24H,HOUU    ;计时单元数据与24比较
            HOUU:  JC   SET6           ;小于24转SET6循环
                   LCALL  CLR0           ;大于或等于24时清0操作
                   AJMP   SET6           ;跳转到SET6循环
           SETOUT: JNB    P3.7,SETOUT1   ;调时退出程序。等待键释放
                   LCALL  DISPLAY        ;延时削抖
                   JNB    P3.7,SETOUT    ;是抖动，返回SETOUT再等待
                   CLR    01H            ;清调小时标志
                   CLR    00H            ;清调分标志
                   CLR    02H            ;清闪烁标志
                   CLR    TR1            ;关闭定时器T1
                   CLR    ET1            ;关定时器T1中断
                   SETB   TR0            ;开启定时器T0
                   SETB   ET0            ;开定时器T0中断（计时开始）
                   LJMP  START1         ;跳回主程序
            SET1:  LCALL      DISPLAY        ;键释放等待时调用显示程序（调分）
                   AJMP       SET2           ;防止键按下时无时钟显示
            SET3:  LCALL      DISPLAY        ;等待调分按键时时钟显示用
                   AJMP       SET4
            SET5:  LCALL      DISPLAY        ;键释放等待时调用显示程序（调小时）
                   AJMP       SETHH1         ;防止键按下时无时钟显示
            SET7:  LCALL      DISPLAY        ;等待调小时按键时时钟显示用
                   AJMP       SET6
         SETOUT1:  LCALL      DISPLAY        ;退出时钟调整时键释放等待
                   AJMP       SETOUT         ;防止键按下时无时钟显示
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;           显示程序                  ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; 显示数据在70H-75H单元内，用六位LED共阳数码管显示，P1口输出段码数据，P3口作
; 扫描控制，每个LED数码管亮1MS时间再逐位循环。
          DISPLAY: MOV   R1,#70H        ;指向显示数据首址
                   MOV   R5,#0FEH       ;扫描控制字初值
             PLAY: MOV   A,R5           ;扫描字放入A
                   MOV   P3,A           ;从P3口输出
                   MOV   A,@R1          ;取显示数据到A
                   MOV   DPTR,#TAB      ;取段码表地址
                   MOVC  A,@A+DPTR      ;查显示数据对应段码
                   ANL        P1,#80H
                   ORL   P1,A           ;段码放入P1口
                   LCALL  DL1MS          ;显示1MS
                   INC   R1             ;指向下一地址
                   MOV   A,R5           ;扫描控制字放入A
                   JNB   ACC.5,ENDOUT   ;ACC.5=0时一次显示结束
                   RL   A              ;A中数据循环左移
                   MOV   R5,A           ;放回R5内
                   AJMP  PLAY           ;跳回PLAY循环
           ENDOUT: SETB  P3.5           ;一次显示结束，P3口复位
                   ORL   P1,#7FH        ;P1口复位
                   RET                       ;子程序返回
             TAB:  DB 40H,79H,24H,30H,19H,12H,02H,78H,00H,10H,7FH
;共阳段码表          "0""1""2" "3""4""5""6""7" "8""9""不亮"
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;           延时程序                  ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;1MS延时程序，LED显示程序用
             DL1MS: MOV  R6,#14H
             DL1:   MOV  R7,#19H
             DL2:   DJNZ  R7,DL2
                    DJNZ  R6,DL1
                    RET

;*********************************************************
;20MS延时程序，采用调用显示子程序以改善LED的显示闪烁现象
           DS20MS: ACALL   DISPLAY
                   ACALL  DISPLAY
                   ACALL  DISPLAY
                   RET

;*********************************************************
;延时程序，用作按键时间的长短判断
           DL1S:   LCALL      DL05S
                   LCALL      DL05S
                   RET
          DL05S:   MOV        R3,#20H      ;8毫秒*32=0.196秒
          DL05S1:  LCALL      DISPLAY
                   DJNZ       R3,DL05S1
                   RET
                   END                     ;程序结束

89C2051带音乐的电子闹钟(已测试OK)

相关链接:http://www.cnieee.com/mcu/MCUYJ/200805/3780.html

3万 · 2008-6-2 07:29

3万 · 2008-6-2 07:32

中央c组里的A＝440Hz
12个半音阶相邻关系是12√2 (2开12次方≈1.0594631)
例如 A＝440Hz
     bB＝440Hz x 1.0594631 ＝ 466.16Hz
      B＝466.16Hz  x 1.0594631 ＝ 493.88Hz
      C＝493.88Hz x 1.0594631 ＝ 523.25Hz

这是本人一个产品中的音乐单元,单音演奏的,多重和音不宜用这方法,一般用硬件的音源加单片机控制方法完成,有兴趣可去合泰网站http://www.holtek.com.cn/docum/consumer/8950.htm看看.ht8950提供了一个产生乐音包络用的硬件平台(a/d,d/a等),用软波表数据来完成音阶及包络,单片机只是进行控制,以前8bit声卡中ym3812与此差不多功能.

中央C的A音为440Hz,半音价之间关系为2开12次方(12√2＝1.05946)
中央C的#A音为440Hz*1.05946＝466.163Hz
中央C的B音为440Hz*1.05946*1.05946＝493.883Hz
用定时器来模拟这个频率,精度取决于时钟快慢,一般小数点后保留一位,音准已可忍受了,生日快乐芯片是小数点前一位的,耳朵容易听坏的拉.

cpu用89c51,p1.7输出乐音,接无源蜂鸣器的驱动三极管基极

        ORG     0000H
        AJMP    CSH             ;主程序进入点
        ORG     000BH
        LJMP    TIM0            ;定时中断T0入口
;
;**********
;* 初始化 *
;**********
;
        ORG     0020H
CSH:    MOV     R0,#7FH         ;内部RAM(00H～7FH)清零
CSH1:   MOV     @R0,#00H
        DJNZ    R0,CSH1
        MOV     SP,#60H         ;堆栈60H～7FH,【使用89C51】
        MOV     TMOD,#01H       ;TMOD=11H,T0作16位计数器(4M晶振)
        CLR     TCON.4          ;T0禁止动作
        SETB    IE.1            ;T0允许中断
        SETB    PT0             ;T0中断优先
        SETB    IE.7            ;系统允许中断
;
;**********
;* 主程序 *
;**********
;
MAIN:   MOV     5CH,#00         ;取简码谱指针
        LCALL   MUSIC
        MOV     5CH,#49         ;取简码谱指针
        LCALL   MUSIC
        MOV     5CH,#66         ;取简码谱指针
        LCALL   MUSIC
        MOV     5CH,#100        ;取简码谱指针
        LCALL   MUSIC
        MOV     5CH,#108        ;取简码谱指针
        LCALL   MUSIC
        MOV     5CH,#136        ;取简码谱指针
        LCALL   MUSIC
        MOV     5CH,#174        ;取简码谱指针
        LCALL   MUSIC
        AJMP    MAIN
;
;*************************
;* 音乐子程序 MUSIC      *
;* 入口: 5CH←简码谱指针 *
;*************************
;
MUSIC:  MOV     A,5CH           ;简码谱指针装入A
        MOV     DPTR,#TABLE     ;至TABLE取简码
        MOVC    A,@A+DPTR
        MOV     R2,A            ;取到的简码暂存于R2
        JZ      END1            ;是否取到00(结束码)?
        ANL     A,#0FH          ;不是,则取低四位(节拍码)
        MOV     R6,A            ;将节拍码存入R6
        MOV     A,R2            ;将取到的简码再装入R2
        SWAP    A               ;高低四位交换
        ANL     A,#0FH          ;取低四位(音符码)
        JNZ     SING            ;取到的音符码是否为0?
        CLR     TR0             ;是,则不发音
        AJMP    D1              ;跳到D1
;
SING:   DEC     A               ;取到的音符码减1
        MOV     4BH,A           ;存入(4BH)
        RL      A               ;乘2
        MOV     DPTR,#TABLE1    ;至TABLE1取相对的高字节计数值
        MOVC    A,@A+DPTR
        MOV     TH0,A           ;取到的高字节存入TH0
        MOV     4AH,A           ;取到的高字节存入(4AH)
        MOV     A,4BH           ;再装入取到的音符码
        RL      A               ;乘2
        INC     A               ;加1
        MOVC    A,@A+DPTR       ;至TABLE1取相对的低位
        MOV     TL0,A           ;取到的低字节存入TL0
        MOV     49H,A           ;取到的低字节存入(49H)
        SETB    TR0             ;启动TIMER0
D1:     CALL    DELAY           ;基本单位时间1/4拍187毫秒
        INC     5CH             ;取简码谱指针加1
        AJMP    MUSIC           ;取下一个码
DD1:    RET
;
STOP:   NOP
;       JB      P3.7,STOP1      ;在软件延时中掺插做其他动作
;       SETB    P2.7            ;P2.7←"1"
        NOP
        NOP
STOP0:  NOP
        RET
STOP1:  NOP
;       JB      P3.6,STOP0    ;在软件延时中掺插做其他动作
;       SETB    P2.6            ;P2.6←"1"
        RET
;
END1:   CLR     TR0             ;停止TIMER0
        RET
;
TIM0:   PUSH    A               ;将A的值暂存于堆栈区
        PUSH    PSW             ;将PSW的值暂存于堆栈区
        MOV     TL0,49H         ;重设计数值
        MOV     TH0,4AH
        CPL     P1.7            ;将输出端P1.7取反(P1.7接至无源蜂鸣器)
        POP     PSW             ;至堆栈区取回PSW的值
        POP     A               ;至堆栈区取回A的值
        RETI                    ;返回主程序
;
DELAY:  MOV     R7,#02          ;187毫秒
D2:     MOV     R4,#24
D3:     MOV     R3,#48
        DJNZ    R3,$
        ACALL   STOP            ;在软件延时中掺插做其他动作
        DJNZ    R4,D3
        DJNZ    R7,D2
        DJNZ    R6,DELAY        ;决定节拍
        RET
;                 .5   .6     .7    1
TABLE1: DW      65111,65150,65199,65217   ;4M晶振时的定时中断时间常数
;                  2    3     4     5     ;若采用其它频率,则要根据乐音的
        DW      65252,65283,65297,65323   ;频率计算,例中央C的A音为440Hz,
;                  6    7     1`    2`    ;440Hz＝2.273ms,把T0设置为2.273ms
        DW      65347,65367,65377,65394   ;中断即可发出A音.
;                 3`    4`    #6
        DW      65410,65417,65357
;
;***************************************************************
;* 音符代码  1  2  3  4  5  6  7  8  9  A  B  C  D  E  F   0   *
;* 音高     .5 .6 .7  1  2  3  4  5  6  7  1` 2` 3` 4` 5` 休止 *
;*-------------------------------------------------------------*
;* 节拍代码  1   2   3  4   5      6    8   A    C   F         *
;* 节拍     1/4 2/4 3/4 1 1(1/4) 1(1/2) 2 2(1/2) 3 3(3/4)      *
;*-------------------------------------------------------------*
;* 结束代码 00H                                                *
;*-------------------------------------------------------------*
;* 乐谱格式  每字节的高字节为音符代码,低字节为节拍代码         *
;*-------------------------------------------------------------*
;* 例子:        ⑴  ⑵  ⑶  ⑷  ⑸  ⑹  ⑺  ⑻  ⑼  ⑽  ⑾     *
;*      DB      A4H,02H,84H,02H,A4H,02H,84H,02H,D8H,04H,00H    *
;*      ⑴ A→唱"7" , 4→ 1 拍                                 *
;*      ⑵ 0→休止  , 2→2/4拍                                 *
;*      ⑶ 8→唱"5" , 4→ 1 拍                                 *
;*      ⑷ 0→休止  , 2→2/4拍                                 *
;*      ⑸ A→唱"7" , 4→ 1 拍                                 *
;*      ⑹ 0→休止  , 2→2/4拍                                 *
;*      ⑺ 8→唱"5" , 4→ 1 拍                                 *
;*      ⑻ 0→休止  , 2→2/4拍                                 *
;*      ⑼ D→唱"3`", 8→ 2 拍                                 *
;*      ⑽ 0→休止  , 4→ 1 拍                                 *
;*      ⑾ 00H→乐曲结束                                       *
;***************************************************************
;
TABLE:
;【00】
        DB      98H,02H,B4H,01H,94H,01H,68H,02H,94H,01H
        DB      64H,01H,48H,02H,64H,01H,44H,01H,28H,02H
        DB      64H,01H,94H,01H,B4H,01H,94H,01H,B4H,01H
        DB      94H,01H,B4H,01H,D4H,01H,94H,01H,64H,01H
        DB      44H,01H,64H,01H,98H,02H,01H,01H,00H
;【49】
        DB      A4H,02H,84H,02H,A4H,02H,84H,02H,D8H,04H
        DB      C8H,01H,01H,01H,01H,01H,00H
;【66】
        DB      42H,52H,62H,72H,82H,92H,A2H,B2H,42H,52H
        DB      62H,72H,82H,92H,A2H,B2H,00H
;【100】
        DB      61H,81H,B1H,D1H,B1H,81H,61H,00H
;【108】
        DB      11H,41H,61H,81H,61H,41H,11H,00H
;【136】
        DB      24H,04H,34H,04H,44H,04H,54H,04H,64H,04H,44H,04H,64H,04H,94H,04H
        DB      83H,01H,93H,01H,83H,01H,63H,01H,46H,02H,66H,02H
        DB      91H,21H,91H,21H,91H,21H,91H,21H,94H,00H
;【174】
        DB      94H,04H,A4H,04H,B4H,04H,C4H,04H,D4H,04H
        DB      B4H,04H,D8H,08H,C4H,04H,F4H,04H,CCH,00H
;
    END

2万 · 2008-6-2 08:33

2万 · 2008-6-2 08:37

这个设计真差劲...

3万 · 2008-6-2 09:38

象做个无线门铃什么的不重要场合,这种方案是很具竞争力的.
不要拿高消费的手机铃声来比划哦,俺甘拜下风.哈哈

只看该作者 · 2008-6-4 15:20

楼主的24C02也可以省了
华邦的W79E2051 内置128B的EEPROM 兼容AT89C2051
华邦选型指南: www.hi.baidu.com/rtech

89C2051带音乐的电子闹钟(已测试OK)

相关下载

相关帖子

楼主的图

要是俺告诉你,那个音乐芯片可省下,你会咪咪笑的

呵呵,音乐芯片特别是高和弦的和自己做的单音,效果不是差一

不过呢，

在一个I/O口快速地分时输出和弦的各个音符,这种准和弦的高

楼主的24C02也可以省了

十世金身

终身成就奖章

坚毅之洋流

技术领袖奖章